[gentoo-commits] proj/kde:master commit in: kde-frameworks/kservice/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     001fee267742546b596b101937b37b4ff4a96b97
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  3 19:44:38 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Feb  3 20:24:09 2024 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=001fee26

kde-frameworks/kservice: 5.115.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/kservice/kservice-5.115.0.ebuild | 50 +++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/kde-frameworks/kservice/kservice-5.115.0.ebuild b/kde-frameworks/kservice/kservice-5.115.0.ebuild
new file mode 100644
index 0000000000..294e9bc355
--- /dev/null
+++ b/kde-frameworks/kservice/kservice-5.115.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Advanced plugin and service introspection"
+
+LICENSE="LGPL-2 LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+man"
+
+# requires running kde environment
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kdbusaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
+"
+BDEPEND="
+	app-alternatives/lex
+	app-alternatives/yacc
+	man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DAPPLICATIONS_MENU_NAME=kf5-applications.menu
+		$(cmake_use_find_package man KF5DocTools)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# bug 596316
+	dosym kf5-applications.menu /etc/xdg/menus/applications.menu
+}