[gentoo-commits] repo/gentoo:master commit in: dev-python/virtualenvwrapper/

["Sam James" <sam@gentoo.org>]

commit:     64e1cdd5bc32695263ba640629ca63bb54172835
Author:     Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Mon Jan 29 14:21:32 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jan 30 11:32:29 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=64e1cdd5

dev-python/virtualenvwrapper: add 6.1.0

Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35071
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/virtualenvwrapper/Manifest              |  1 +
 .../virtualenvwrapper-6.1.0.ebuild                 | 71 ++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-python/virtualenvwrapper/Manifest b/dev-python/virtualenvwrapper/Manifest
index 0c4c69b6e1c1..4b172b0ff2f6 100644
--- a/dev-python/virtualenvwrapper/Manifest
+++ b/dev-python/virtualenvwrapper/Manifest
@@ -1 +1,2 @@
 DIST virtualenvwrapper-6.0.0.tar.gz 95407 BLAKE2B b2a6a7a58be23e1cf0642d780d8fc53e9aef6e44703fa15a2e7627db3c3e12024b33da75b591897ea5181ed5407eb2d52e96f56d7026c083a03e13f94165d9e4 SHA512 ab805b61a9f81e0b0842182686a88fcf07e41ad7206484f002110c693ca6076e2a88fefbef8b7409838082ed7e7a43f61f1a0006a314cb1d71efb943dc6fdede
+DIST virtualenvwrapper-6.1.0.tar.gz 95880 BLAKE2B 86d37682148ee132f9be5c4554de3c770c0f1c3055441bbce080d94da6fa83fc138a15c4c7edbb525e0c303c3c2ba5c1b1ee23260ea5bafaab157b3699b39b87 SHA512 78e09956132862fbf1caf53cb6c9375aa3718685f72d8f3fb61e402e6b26e8568d5b3a3ed18142b14f3b2691f89e6f912782e813d8139dc71ceb7e47bde8d0b0

diff --git a/dev-python/virtualenvwrapper/virtualenvwrapper-6.1.0.ebuild b/dev-python/virtualenvwrapper/virtualenvwrapper-6.1.0.ebuild
new file mode 100644
index 000000000000..3a8f01c1583b
--- /dev/null
+++ b/dev-python/virtualenvwrapper/virtualenvwrapper-6.1.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Set of extensions to Ian Bicking's virtualenv tool"
+HOMEPAGE="
+	https://github.com/python-virtualenvwrapper/virtualenvwrapper/
+	https://pypi.org/project/virtualenvwrapper/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/stevedore[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/virtualenv-clone[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	')
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/pip[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/virtualenvwrapper-6.0.0-remove-use-of-which.patch"
+	"${FILESDIR}/virtualenvwrapper-4.8.4_p20230121-override-default-python-executable.patch"
+)
+
+src_prepare() {
+	default
+
+	# specify default python interpeter to align with PYTHON_SINGLE_TARGET
+	sed -i -e "s:@@GENTOO_PYTHON_EXECUTABLE@@:${PYTHON}:" virtualenvwrapper.sh || die
+
+	# remove tests which require an internet connection
+	rm tests/test_mkvirtualenv_install.sh || die
+	rm tests/test_mkvirtualenv_requirements.sh || die
+
+	# remove tests which require functional git repos with remotes
+	sed -i -e '/test_wipeenv_\(pip_e\|develop\) () {/,/}/ d' tests/test_wipeenv.sh || die
+}
+
+python_test() {
+	# tests have unusual expectations
+	local -x HOME="${HOME%/}"
+	local -x USER="${USER}"
+
+	cp -a "${BUILD_DIR}"/{install/usr,test} || die
+	local -x VIRTUAL_ENV="${BUILD_DIR}/test"
+
+	bash ./tests/run_tests "${VIRTUAL_ENV}" || die "Tests failed under ${EPYTHON}"
+}