[gentoo-commits] repo/gentoo:master commit in: dev-build/gn/

["Sam James" <sam@gentoo.org>]

commit:     69e8c3151a5fc0177ab0071fc21a22062ff3a271
Author:     Matt Jolly <Matt.Jolly <AT> footclan <DOT> ninja>
AuthorDate: Sat Jan 27 06:01:12 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jan 27 07:32:03 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=69e8c315

dev-build/gn: add 0.2143

Signed-off-by: Matt Jolly <Matt.Jolly <AT> footclan.ninja>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-build/gn/Manifest         |  1 +
 dev-build/gn/gn-0.2143.ebuild | 66 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-build/gn/Manifest b/dev-build/gn/Manifest
index eacd3f2768e5..7573d37558ea 100644
--- a/dev-build/gn/Manifest
+++ b/dev-build/gn/Manifest
@@ -3,3 +3,4 @@ DIST gn-0.2077.tar.xz 735596 BLAKE2B 48da6c1b08746d364974c94a8395708ba44f4fb88a4
 DIST gn-0.2088.tar.xz 736408 BLAKE2B 23cb932c6fa1711472e0369b5c9271dd28b1d1a8eee40366295ea576fb0d913f3e01dd802df718d6d55ad27b566b0fae5da0cb03167e38df46bbda284b26f99c SHA512 be1d0a0095a7de9fc130935d45c610ab77dd9451822b33c344ac79d096828752bab04b81183eaa35b654abbb76748ce13751c04d44968d08643b6cd89f3fe8f7
 DIST gn-0.2114.tar.xz 740080 BLAKE2B 51c6d373ed7a33673e76fe8bb40f727193c6e1172fba328916fd2229d1e350cea5c51da734edf6dbf4c0b7bed61a590424484d4150e7cd4c890abba7f43251c7 SHA512 f5370e45bc2a079b79e4bcfc802fbc6cf67f7674a11311f849699f54775593e75def15323843ef887231891cb06b043863c79c5168e565319a4b73fcffa13738
 DIST gn-0.2122.tar.xz 740444 BLAKE2B df57fb611f26964ed3ac47365080cd043ba4206233450bb39699e78e35b8acff918e94efe4e7cea957199dd2f441dfcf31566e7d64ad10aace9d2c1d538ed6ac SHA512 80c330eac876fc0d6f46038b96eefd19bc1b6e5e89515489c1d02f82675213174fba394398ffc1bdd1405ddcd11b60c2870f3076296390976da74012867faf39
+DIST gn-0.2143.tar.xz 742220 BLAKE2B bfc33c4f323e9a7182c57c0c832866b48ae0877cfc1eeb42518a97ac6a64ab70e5bc81855f1c5201a49a7842e284b7a9042e1666f79c6182539076cfef6bb128 SHA512 8450947abf904faf47951ebb8336f4e2c54cb50fd6044750206a0d2a4284107670aeaec9d520374dfdb8baa1ca3b6dae5158ae564dcd40a2898f3614c003e7eb

diff --git a/dev-build/gn/gn-0.2143.ebuild b/dev-build/gn/gn-0.2143.ebuild
new file mode 100644
index 000000000000..b2efbd2b6573
--- /dev/null
+++ b/dev-build/gn/gn-0.2143.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2018-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit edo ninja-utils python-any-r1 toolchain-funcs
+
+DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
+HOMEPAGE="https://gn.googlesource.com/"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gn.googlesource.com/gn"
+else
+	# The version number is derived from `git describe HEAD --abbrev=12`
+	SRC_URI="https://deps.gentoo.zip/dev-build/gn/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	app-alternatives/ninja
+"
+
+PATCHES=(
+	"${FILESDIR}"/gn-gen-r5.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	python_setup
+	tc-export AR CC CXX
+	unset CFLAGS
+	set -- ${EPYTHON} build/gen.py --no-last-commit-position --no-strip --no-static-libstdc++ --allow-warnings
+	edo "$@"
+	cat >out/last_commit_position.h <<-EOF || die
+	#ifndef OUT_LAST_COMMIT_POSITION_H_
+	#define OUT_LAST_COMMIT_POSITION_H_
+	#define LAST_COMMIT_POSITION_NUM ${PV##0.}
+	#define LAST_COMMIT_POSITION "${PV}"
+	#endif  // OUT_LAST_COMMIT_POSITION_H_
+	EOF
+}
+
+src_compile() {
+	eninja -C out gn
+}
+
+src_test() {
+	eninja -C out gn_unittests
+	out/gn_unittests || die
+}
+
+src_install() {
+	dobin out/gn
+	einstalldocs
+
+	insinto /usr/share/vim/vimfiles
+	doins -r misc/vim/{autoload,ftdetect,ftplugin,syntax}
+}