[gentoo-commits] repo/gentoo:master commit in: app-text/libetonyek/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     4e67154493bda9c09588d4b97dcc96803facfe94
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 26 23:02:30 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Jan 27 00:45:59 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4e671544

app-text/libetonyek: Support --with-mdds=2.1

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/libetonyek/libetonyek-0.1.10-r2.ebuild | 65 +++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/app-text/libetonyek/libetonyek-0.1.10-r2.ebuild b/app-text/libetonyek/libetonyek-0.1.10-r2.ebuild
new file mode 100644
index 000000000000..b3efde34cbfa
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.10-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/librevenge
+	dev-libs/libxml2
+	>=dev-util/mdds-2.0:1=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	media-libs/glm
+	dev-build/libtool
+	test? ( dev-util/cppunit )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+	)
+	if has_version ">=dev-util/mdds-2.1"; then
+		myeconfargs+=( --with-mdds=2.1 )
+	else
+		myeconfargs+=( --with-mdds=2.0 )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}