[gentoo-commits] repo/gentoo:master commit in: dev-python/tavern/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     45e4bc32a7b5a7e43f560392d2a880895fc2cccb
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 23 17:47:44 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue Jan 23 18:18:39 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45e4bc32

dev-python/tavern: add 2.9.0

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/tavern/Manifest            |  1 +
 dev-python/tavern/tavern-2.9.0.ebuild | 65 +++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index 001753ee2d23..b94f9a0f0cf5 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1,2 +1,3 @@
 DIST tavern-2.7.1.gh.tar.gz 220388 BLAKE2B 3e689ff0c29ddf2e53e018f86c79ea7e4e89e586d5f28b79c93263a10c4e7738fbf4c66df81fd55bc13a812223e538726f3f9b9f8bdbb94e7f043e90c70af2ce SHA512 de2822ec746c2ccb27a401c07bc5618539e4ad309e56437d0c66669612f48658fc352e42a0b4db94f9c183a159bbdcbeabdf30bebeac03c5f6a9f51bc7014b76
 DIST tavern-2.8.0.gh.tar.gz 246475 BLAKE2B 373d58205462bbe34deffdcb1f87700e121e9fceee77700bda7ef76787d3c1b4ce2fdba8eb4a4e1369814665ed0c6562268f8acfe3b85eb92ff260dd413caaee SHA512 b54ba992f328623b8bddbafd67eb7e124718aa7e01435ac3c1132451b450e7a8af49618fec16c0d47d0300c5cafe78ffab6991abde880986d7381c8b885e22ad
+DIST tavern-2.9.0.gh.tar.gz 246867 BLAKE2B 77cb0cd54223ad401dba429abae503b102b208603e3ecaf0cdc84a71f0928beabd0b783ef5fbf448186d60e400c01ab67505a92031a097bcb68e4cbdd67d07d7 SHA512 4401e9c96f4f721f8d28f03e2a69bdc5e0daeb348b5a3356f1d9a996f81377f9fc5d8481f58dd6106904c89177324e541595e325f6d1c18e9028fa01dd022d4d

diff --git a/dev-python/tavern/tavern-2.9.0.ebuild b/dev-python/tavern/tavern-2.9.0.ebuild
new file mode 100644
index 000000000000..74fcee9d1337
--- /dev/null
+++ b/dev-python/tavern/tavern-2.9.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+	>=dev-python/paho-mqtt-1.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7[${PYTHON_USEDEP}]
+	>=dev-python/python-box-6[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/Faker[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires grpc
+		tests/unit/test_extensions.py::TestGrpcCodes
+	)
+	local EPYTEST_IGNORE=(
+		# require grpc*
+		tavern/_plugins/grpc
+		tests/unit/tavern_grpc
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p tavern
+}