[gentoo-commits] repo/gentoo:master commit in: dev-python/podman/

["Michał Górny" <mgorny@gentoo.org>]

commit:     bf5ea897ac36149fe43adcffd6585d3bd4e47871
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 23 04:34:40 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan 23 04:38:56 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf5ea897

dev-python/podman: Bump to 4.9.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/podman/Manifest            |  1 +
 dev-python/podman/podman-4.9.0.ebuild | 53 +++++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-python/podman/Manifest b/dev-python/podman/Manifest
index c80e111b2ae0..113ad4e48681 100644
--- a/dev-python/podman/Manifest
+++ b/dev-python/podman/Manifest
@@ -1,2 +1,3 @@
 DIST podman-py-4.8.1.gh.tar.gz 182099 BLAKE2B 345cf5374baeab6760dd0494a105963658a3c0cff5a8e283be7ac7e6f8f9acba742022628cfde7f978d08f99a680b2c4aebd1d5682553b3bd0f5609d3265c93d SHA512 35f62f16f61ec0a5ebfeede0e6e8fe5528b896315e000529a0aff38bf572b3b558e5066f034ba38a755899e1b6a7a26623406c677a6c7f3aad777094377b5755
 DIST podman-py-4.8.2.gh.tar.gz 182212 BLAKE2B 3a6fc69d3d1512962a019bd1ed6087cc1f8ae4e42de42660f023d1125c4442a44208618115c4386bc9a70dd10b8154e253d30479d31675d1f46f584b6eeffee1 SHA512 78a6bb76a8ba4d4598adb7b353f5fb919848f98f1c2d6de6b1de9ff24d8672e9d0ffd102fa8bdf16a24aa289d0f724932e8b990df19b926c4424c9f7ac2b1ada
+DIST podman-py-4.9.0.gh.tar.gz 182639 BLAKE2B fce3efa75658bb29513fdb55fa8b51d41401a49d58c2ea3c17c037e435f1f822090c6cc12b1afd06aec7e96c2541abb898fc37a0d2a62fcc5cddeeaf7832a0c0 SHA512 73488ccd3e910284410a43ec607cefdab3b8f3478617b95d5a6efd6f817a3eaced1a5ac9993d13c0104bad1bcd868507d544ef0396202003bb2f8b024901396c

diff --git a/dev-python/podman/podman-4.9.0.ebuild b/dev-python/podman/podman-4.9.0.ebuild
new file mode 100644
index 000000000000..9567fabe9519
--- /dev/null
+++ b/dev-python/podman/podman-4.9.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+MY_P=podman-py-${PV/_p/.post}
+DESCRIPTION="A library to interact with a Podman server"
+HOMEPAGE="
+	https://github.com/containers/podman-py/
+	https://pypi.org/project/podman/
+"
+SRC_URI="
+	https://github.com/containers/podman-py/archive/v${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.24[${PYTHON_USEDEP}]
+	>=dev-python/rich-12.5.1[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.3[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-python/requests-mock-1.11.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		podman/tests/unit/test_volumesmanager.py::VolumesManagerTestCase::test_get_404
+	)
+
+	# integration tests require a workable podman server,
+	# and it doesn't seem to work in ebuild env
+	epytest podman/tests/unit
+}