[gentoo-commits] repo/gentoo:master commit in: dev-python/uvicorn/

["Michał Górny" <mgorny@gentoo.org>]

commit:     cf61e27611bc8a436d09033bea8a3eaa401f5d20
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 23 04:34:01 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jan 23 04:38:55 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cf61e276

dev-python/uvicorn: Bump to 0.27.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/uvicorn/Manifest              |  1 +
 dev-python/uvicorn/uvicorn-0.27.0.ebuild | 72 ++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-python/uvicorn/Manifest b/dev-python/uvicorn/Manifest
index c37fd28234f3..db3685c79b14 100644
--- a/dev-python/uvicorn/Manifest
+++ b/dev-python/uvicorn/Manifest
@@ -1,2 +1,3 @@
 DIST uvicorn-0.25.0.gh.tar.gz 717386 BLAKE2B f0a472676a732d7807137f157c95574584d882bf9ae8531c4e2c1164ebe9eec2172da62f72f07032ada422b7932f221457686aa22ab6fbceac57685ad91920b8 SHA512 19c1e6438c40ab1b1d30c9c9c84d65f2dc661197adcc6be3d7825223d933d4554ec388323e16452ef0409476766af1ae18bb3252a391099bd2e2bfe2b6c4abb2
 DIST uvicorn-0.26.0.gh.tar.gz 717758 BLAKE2B 1ac4d28a6351a8e9fc9d4e0481237dd8b3265afcfd2c554093299bb6d03570809edf44a1c6278441c1a8611d380aacbfa99986ebac99b19e65d055c78c28e494 SHA512 3b561f3b5335bd52093d5aab2ab9db101a2a36f06179fe02a177a5de4dc336f2aaf700b45ceb7c0952d0b3e5e2a3bdf0387b978ac46af96def409e189bacfa23
+DIST uvicorn-0.27.0.gh.tar.gz 718371 BLAKE2B a8e5504f673add3e0babb2fefa9d045adc34062b7746c1149c1a7a467073495f07d26b23f0d81678698f41d7887eb28aeaffe29f29706c84be39d5b8f3d85b1b SHA512 2337223e30dcc89a32babfce6b381f53225df3ea319e13ae8b758b4a1801ec49a1e8c2caa148757fe715504b75934a6a75156c6e7146fb21335905f1425f89fa

diff --git a/dev-python/uvicorn/uvicorn-0.27.0.ebuild b/dev-python/uvicorn/uvicorn-0.27.0.ebuild
new file mode 100644
index 000000000000..f851c31a0cff
--- /dev/null
+++ b/dev-python/uvicorn/uvicorn-0.27.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Lightning-fast ASGI server implementation"
+HOMEPAGE="
+	https://www.uvicorn.org/
+	https://github.com/encode/uvicorn/
+	https://pypi.org/project/uvicorn/
+"
+# as of 0.21.0, no tests in sdist
+SRC_URI="
+	https://github.com/encode/uvicorn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/h11-0.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/a2wsgi[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		>=dev-python/websockets-10.4[${PYTHON_USEDEP}]
+		dev-python/wsproto[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/cryptography[${PYTHON_USEDEP}]
+			dev-python/trustme[${PYTHON_USEDEP}]
+			dev-python/watchfiles[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# too long path for unix socket
+		tests/test_config.py::test_bind_unix_socket_works_with_reload_or_workers
+	)
+	case ${EPYTHON} in
+		pypy3)
+			# TODO
+			EPYTEST_DESELECT+=(
+				tests/middleware/test_logging.py::test_running_log_using_fd
+			)
+			;;
+	esac
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "auto reload on file changes" dev-python/watchfiles
+}