[gentoo-commits] repo/gentoo:master commit in: media-libs/libplacebo/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     6173fdd919863dae07e11da584e5455f5cc8245e
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 22 18:33:53 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Jan 22 18:36:46 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6173fdd9

media-libs/libplacebo: add 6.338.2

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-libs/libplacebo/Manifest                  |   1 +
 media-libs/libplacebo/libplacebo-6.338.2.ebuild | 122 ++++++++++++++++++++++++
 2 files changed, 123 insertions(+)

diff --git a/media-libs/libplacebo/Manifest b/media-libs/libplacebo/Manifest
index ad964e340d65..d96b2f12a1f3 100644
--- a/media-libs/libplacebo/Manifest
+++ b/media-libs/libplacebo/Manifest
@@ -1,3 +1,4 @@
 DIST fast_float-5.2.0.tar.gz 84800 BLAKE2B 39133eda20acd5f1f049e8040815a67aee588ab93be4953bde3b9227fb691e099581ef79b12b740437b78a9b4c9007762b44d9726ca07505ad5cb51394d8e3fd SHA512 c703c7cba3c69775317c66a62ce145646fd7d3d063124501e3d6a7deebb8c62c14a2ccdffed18de2d73d9d3a8ba2061ef1d34cc780ee0b6d607935d5f1b1de81
 DIST libplacebo-glad-2.0.4.tar.gz 599932 BLAKE2B 788d2b70222fd09eea02515bdf3cbc147540631bf35fe39f12aa21fdbabf3d229f4234a430217dfaf3363934b8be12dd6a19871049a7b117deb8260ec69f8c67 SHA512 328d0dbe33e69f846d1c54226c6675694404f41e53c4762e6013c7bfe76b0700f0b28f4117a2018a09c9c23ccb6ad94d7b20882fefc2513941a4515686c9b9e7
 DIST libplacebo-v6.338.1.tar.bz2 696577 BLAKE2B c4b1a9830ba91127c78fca30deabbc90c157b0bd9220216c6452866312374b9415f00c6f0c3b573070d4bf26a0c25df96462365d0929dcd022ef5ab84b909e17 SHA512 79e9f800791dcc856ead965f2b0b463ede3313186f248be85e3cf9ec62901043dad72b639f426f858e1fff0bbd9bdcdea48d01a5d3d2218b79e263fa0432bc5b
+DIST libplacebo-v6.338.2.tar.bz2 697450 BLAKE2B 538785bea0003ff49a14b75f26fcd255259ed3b809b4b40be4000ec715808d6603d0139fe872ff2cf4ec13851a03fe63b251d019ef163fbbbfa74a012e0efbe6 SHA512 6577d19590b4d186d721238bd4c6bf940d1e766fe58053673fb5efb4c2c0a4408f29e7a1477328689a30b22eeac8c27548b82c11bfa0bc527d16f691849479c7

diff --git a/media-libs/libplacebo/libplacebo-6.338.2.ebuild b/media-libs/libplacebo/libplacebo-6.338.2.ebuild
new file mode 100644
index 000000000000..af53410bee94
--- /dev/null
+++ b/media-libs/libplacebo/libplacebo-6.338.2.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson-multilib python-any-r1
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://code.videolan.org/videolan/libplacebo.git"
+	inherit git-r3
+else
+	GLAD_PV=2.0.4
+	FASTFLOAT_PV=5.2.0
+	SRC_URI="
+		https://code.videolan.org/videolan/libplacebo/-/archive/v${PV}/libplacebo-v${PV}.tar.bz2
+		https://github.com/fastfloat/fast_float/archive/refs/tags/v${FASTFLOAT_PV}.tar.gz
+			-> fast_float-${FASTFLOAT_PV}.tar.gz
+		opengl? (
+			https://github.com/Dav1dde/glad/archive/refs/tags/v${GLAD_PV}.tar.gz
+				-> ${PN}-glad-${GLAD_PV}.tar.gz
+		)
+	"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Reusable library for GPU-accelerated image processing primitives"
+HOMEPAGE="
+	https://libplacebo.org/
+	https://code.videolan.org/videolan/libplacebo/
+"
+
+LICENSE="
+	LGPL-2.1+
+	|| ( Apache-2.0 Boost-1.0 MIT )
+	opengl? ( MIT )
+"
+SLOT="0/$(ver_cut 2 ${PV}.9999)" # soname
+IUSE="glslang +lcms llvm-libunwind +opengl +shaderc test unwind +vulkan +xxhash"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
+
+# dlopen: libglvnd (glad)
+RDEPEND="
+	lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
+	opengl? ( media-libs/libglvnd[${MULTILIB_USEDEP}] )
+	shaderc? ( media-libs/shaderc[${MULTILIB_USEDEP}] )
+	!shaderc? ( glslang? ( dev-util/glslang:=[${MULTILIB_USEDEP}] ) )
+	unwind? (
+		llvm-libunwind? ( sys-libs/llvm-libunwind[${MULTILIB_USEDEP}] )
+		!llvm-libunwind? ( sys-libs/libunwind:=[${MULTILIB_USEDEP}] )
+	)
+	vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )
+"
+# vulkan-headers is required even with USE=-vulkan for the stub (bug #882065)
+DEPEND="
+	${RDEPEND}
+	dev-util/vulkan-headers
+	xxhash? ( dev-libs/xxhash[${MULTILIB_USEDEP}] )
+"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/jinja[${PYTHON_USEDEP}]')
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.229.1-llvm-libunwind.patch
+	"${FILESDIR}"/${PN}-5.229.1-python-executable.patch
+)
+
+python_check_deps() {
+	python_has_version "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]]; then
+		local EGIT_SUBMODULES=(
+			3rdparty/fast_float
+			$(usev opengl 3rdparty/glad)
+		)
+		git-r3_src_unpack
+	else
+		default
+
+		rmdir "${S}"/3rdparty/fast_float || die
+		mv fast_float-${FASTFLOAT_PV} "${S}"/3rdparty/fast_float || die
+
+		if use opengl; then
+			rmdir "${S}"/3rdparty/glad || die
+			mv glad-${GLAD_PV} "${S}"/3rdparty/glad || die
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+
+	# typically auto-skipped, but may assume usable opengl/vulkan then hang
+	sed -i "/tests += 'opengl_surfaceless.c'/d" src/opengl/meson.build || die
+	sed -i "/tests += 'vulkan.c'/d" src/vulkan/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddemos=false #851927
+		$(meson_use test tests)
+		$(meson_feature lcms)
+		-Dlibdovi=disabled # TODO: package libdovi, ask if you need this
+		$(meson_feature opengl)
+		$(meson_feature opengl gl-proc-addr)
+		$(meson_feature shaderc)
+		$(usex shaderc -Dglslang=disabled $(meson_feature glslang))
+		$(meson_feature unwind)
+		$(meson_feature vulkan)
+		$(meson_feature vulkan vk-proc-addr)
+		-Dvulkan-registry="${ESYSROOT}"/usr/share/vulkan/registry/vk.xml
+		$(meson_feature xxhash)
+	)
+
+	meson_src_configure
+}