[gentoo-commits] repo/proj/guru:master commit in: app-misc/diff-so-fancy/

["David Roman" <davidroman96@gmail.com>]

commit:     8c35e64a7d0561cad798ab0b066bccfee7487fb0
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Sun Jan 21 14:34:18 2024 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Sun Jan 21 14:34:27 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=8c35e64a

app-misc/diff-so-fancy: add 1.4.4

Closes: https://bugs.gentoo.org/819063
Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 app-misc/diff-so-fancy/Manifest                   |  1 +
 app-misc/diff-so-fancy/diff-so-fancy-1.4.4.ebuild | 56 +++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/app-misc/diff-so-fancy/Manifest b/app-misc/diff-so-fancy/Manifest
index c8987d0d13..134b6f9981 100644
--- a/app-misc/diff-so-fancy/Manifest
+++ b/app-misc/diff-so-fancy/Manifest
@@ -1 +1,2 @@
 DIST diff-so-fancy-1.4.3.tar.gz 51800 BLAKE2B e36a30e79d50f9dd0c151ab42e4192563ab0dc9aa30d0aa12e2cf85c29ef8acf9761cc7c19e0067ecf62f5243b667a7d438ab19aaa7150fd93613e11ecbfabf8 SHA512 9c85c0ffcb7235ad985377206e93e56bdac3926f029d8ab8a899a4391339f344049e9bfe4b77df0f2bda29720ab454378218ea3752b97f40b5ac7ba72a5fa047
+DIST diff-so-fancy-1.4.4.tar.gz 188528 BLAKE2B dd4811e17b6b8a0a5a38d105ed92facdfc9b62836995f1b9e87c05a0fe4129706a4552465971bb593105569008cb7f4f3a069294801c07d510a1d9d819475c13 SHA512 477ad58a55ebc765f525b7d16993af18ee5ccf0c9f2835f4a608c6a1a9afa3170f2071dd93b9009dc3c2dab06f700763ac7652d0bedb932a67af23abf4f8884e

diff --git a/app-misc/diff-so-fancy/diff-so-fancy-1.4.4.ebuild b/app-misc/diff-so-fancy/diff-so-fancy-1.4.4.ebuild
new file mode 100644
index 0000000000..cc5da5429e
--- /dev/null
+++ b/app-misc/diff-so-fancy/diff-so-fancy-1.4.4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Good-lookin' diffs. Actually... nah... The best-lookin' diffs"
+HOMEPAGE="https://github.com/so-fancy/diff-so-fancy"
+SRC_URI="https://github.com/so-fancy/diff-so-fancy/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-lang/perl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-util/bats-assert
+		dev-util/bats-support
+	)
+"
+BDEPEND="
+	test? (
+		dev-util/bats
+		dev-vcs/git
+	)
+"
+
+DOCS=( README.md history.md pro-tips.md )
+
+src_prepare() {
+	default
+
+	# fix file paths
+	sed -i "s|test_helper/bats-\(.*\)/load|${EPREFIX}/usr/share/bats-\1/load.bash|" \
+		test/{bugs,diff-so-fancy,git-config}.bats || die
+	sed -i "s|use lib .*;|use lib \"${EPREFIX}/usr/share/diff-so-fancy\";|" diff-so-fancy || die
+
+	# en_US locale is not always available, C is.
+	sed -i "s/LC_CTYPE=.*/LC_CTYPE=C.UTF-8/" test/test_helper/util.bash || die
+}
+
+src_install() {
+	dobin "${PN}"
+
+	insinto "/usr/share/${PN}"
+	doins lib/*
+
+	einstalldocs
+}
+
+src_test() {
+	PERL5LIB=lib bats test || die
+}