[gentoo-commits] repo/gentoo:master commit in: net-libs/libvncserver/

["Sam James" <sam@gentoo.org>]

commit:     cea7c09c70390799b321479a59b597a25f951f9b
Author:     Alexander Tsoy <alexander <AT> tsoy <DOT> me>
AuthorDate: Thu Jan  4 18:58:27 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Jan 20 12:47:50 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cea7c09c

net-libs/libvncserver: always enable gcrypt-based crypto backend

There are a few reasons for that:
- internal crypto backend doesn't support all authentication methods and
  the use of external crypto backend was already forced via REQUIRED_USE
- openssl-based crypto backend is completely broken with openssl-3.0
- build system does not allow to disable openssl-based crypto backend when
  openssl-based TLS backend is enabled without also enabling gcrypt-based
  crypto backend
- all major distros are building with gcrypt-based crypto backend, so it
  is the most tested configuration.

Closes: https://bugs.gentoo.org/893608
Signed-off-by: Alexander Tsoy <alexander <AT> tsoy.me>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../libvncserver/libvncserver-0.9.14-r2.ebuild     | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)

diff --git a/net-libs/libvncserver/libvncserver-0.9.14-r2.ebuild b/net-libs/libvncserver/libvncserver-0.9.14-r2.ebuild
new file mode 100644
index 000000000000..02c596ac0d4b
--- /dev/null
+++ b/net-libs/libvncserver/libvncserver-0.9.14-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_P="LibVNCServer-${PV}"
+
+DESCRIPTION="library for creating vnc servers"
+HOMEPAGE="https://libvnc.github.io/"
+SRC_URI="https://github.com/LibVNC/${PN}/archive/${MY_P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_P}"
+
+# common/d3des.*: https://github.com/LibVNC/libvncserver/issues/88
+LICENSE="GPL-2 GPL-2+ LGPL-2.1+ BSD MIT"
+# no sub slot wanted (yet), see #578958
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
+IUSE="+24bpp +filetransfer gnutls ipv6 +jpeg lzo +png sasl ssl systemd +threads +zlib"
+# https://bugs.gentoo.org/690202
+# https://bugs.gentoo.org/435326
+# https://bugs.gentoo.org/550916
+REQUIRED_USE="
+	filetransfer? ( threads )
+	jpeg? ( zlib )
+	png? ( zlib )
+	ssl? ( !gnutls? ( threads ) )
+"
+
+DEPEND="
+	>=dev-libs/libgcrypt-1.5.3:0=
+	ssl? (
+		!gnutls? ( >=dev-libs/openssl-1.0.2:0= )
+		gnutls? ( >=net-libs/gnutls-2.12.23-r6:0= )
+	)
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	lzo? ( dev-libs/lzo )
+	png? ( >=media-libs/libpng-1.6.10:0= )
+	sasl? ( dev-libs/cyrus-sasl )
+	systemd? ( sys-apps/systemd:= )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1:0= )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS.md README.md )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-crypto-openssl-fix.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_EXAMPLES=OFF
+		-DWITH_FFMPEG=OFF
+		-DWITH_GTK=OFF
+		-DWITH_SDL=OFF
+		-DWITH_GCRYPT=ON
+		-DWITH_24BPP=$(usex 24bpp ON OFF)
+		-DWITH_TIGHTVNC_FILETRANSFER=$(usex filetransfer ON OFF)
+		-DWITH_GNUTLS=$(usex gnutls $(usex ssl ON OFF) OFF)
+		-DWITH_IPv6=$(usex ipv6 ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_LZO=$(usex lzo ON OFF)
+		-DWITH_OPENSSL=$(usex gnutls OFF $(usex ssl ON OFF))
+		-DWITH_PNG=$(usex png ON OFF)
+		-DWITH_SASL=$(usex sasl ON OFF)
+		-DWITH_SYSTEMD=$(usex systemd ON OFF)
+		-DWITH_THREADS=$(usex threads ON OFF)
+		-DWITH_ZLIB=$(usex zlib ON OFF)
+	)
+	cmake_src_configure
+}