[gentoo-commits] repo/proj/guru:dev commit in: dev-python/asyncpg/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     d26acc7462fb6ea31b629cffb8b253ef97077a6a
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Wed Jan 17 13:45:32 2024 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Wed Jan 17 13:45:47 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=d26acc74

dev-python/asyncpg: add 0.29.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 dev-python/asyncpg/Manifest              |  1 +
 dev-python/asyncpg/asyncpg-0.29.0.ebuild | 67 ++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-python/asyncpg/Manifest b/dev-python/asyncpg/Manifest
index 2422f516e0..057e9f59e0 100644
--- a/dev-python/asyncpg/Manifest
+++ b/dev-python/asyncpg/Manifest
@@ -1 +1,2 @@
 DIST asyncpg-0.27.0.tar.gz 808881 BLAKE2B e4fe88346a3fb4d9b6ce74a4e12db333f1aefd8844d6b08091a1e507a56754bb74dcbdd1b43329f1df24725f03c808a1862c8c4587c9ec95c4800f30ab78458c SHA512 66d4e16cba8ebebfa0403c7d3b1d3ee1b9b8f55a9b70f57e809d28161873d74750152e6ed548b17ceb97ca84f7a669a5fa503c824a861b295db731f86bfb0137
+DIST asyncpg-0.29.0.tar.gz 820455 BLAKE2B 9bb5606dfb103e066dcfd15c327fe8a8135bf4433c816dc354d84227e40b9f18bb2788ead0dd25b087f97b3113645b6dcfd8991a7bb6e2e71528d122c41105d5 SHA512 5db979496323fcf4068d5de111b52f2ae1ad9efe68f80c28e6303ad936eb051d1792409f1e31fb86dc35caad5ef9b92c40e4f6dcbcccc3907ab2247f61db5504

diff --git a/dev-python/asyncpg/asyncpg-0.29.0.ebuild b/dev-python/asyncpg/asyncpg-0.29.0.ebuild
new file mode 100644
index 0000000000..2cfb50ff96
--- /dev/null
+++ b/dev-python/asyncpg/asyncpg-0.29.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )  # doesn't build with pypy3
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="PostgreSQL driver for asyncio"
+HOMEPAGE="
+	https://pypi.org/project/asyncpg/
+	https://github.com/MagicStack/asyncpg
+"
+
+LICENSE="Apache-2.0 PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-4.0.3[${PYTHON_USEDEP}]
+	' python3_{10..11})
+"
+BDEPEND="
+	<dev-python/cython-3[${PYTHON_USEDEP}]
+	test? (
+		dev-db/postgresql[server]
+		dev-python/uvloop[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# checks versions from env variables
+	"${S}"/tests/test__environment.py
+	# runs flake8 (???)
+	"${S}"/tests/test__sourcecode.py
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinxcontrib-asyncio \
+	dev-python/sphinx-rtd-theme
+
+src_prepare() {
+	# remove pre-generated Cython sources
+	rm asyncpg/{pgproto/pgproto,protocol/protocol}.c || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	use debug && \
+		export ASYNCPG_DEBUG=1
+
+	distutils-r1_src_configure
+}
+
+python_test() {
+	cd "${T}" || die
+	for opt in "" "1"; do
+		einfo "  testing with USE_UVLOOP='${opt}'"
+		USE_UVLOOP="${opt}" epytest "${S}"/tests
+	done
+}