[gentoo-commits] repo/gentoo:master commit in: dev-python/pyspelling/

["Michał Górny" <mgorny@gentoo.org>]

commit:     4ad87b42ff3efb5cda20078726ab6da98c675ba9
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 13 06:56:32 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 13 08:19:52 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4ad87b42

dev-python/pyspelling: Bump to 2.10

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyspelling/Manifest               |  1 +
 dev-python/pyspelling/pyspelling-2.10.ebuild | 67 ++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-python/pyspelling/Manifest b/dev-python/pyspelling/Manifest
index d63c2bca40f3..de8f00e7b5b4 100644
--- a/dev-python/pyspelling/Manifest
+++ b/dev-python/pyspelling/Manifest
@@ -1 +1,2 @@
+DIST pyspelling-2.10.gh.tar.gz 152528 BLAKE2B 47ef182fb09bc3ec44b6c15da76f0d53266276ec807036378a3f5ae94daf98d3b3a49995ce2d12044c81743ee76d8b79547d84ae3c820be1f30161c75a654ba4 SHA512 dfe0d0c211555331dd6d97e06ce64ac2efbe5cc6172f684ca3b1802a8454b957781022375a9a53a2f522f4bd3bbf4e5892ab6be266bcfbe69c4861d95db00ab0
 DIST pyspelling-2.9.gh.tar.gz 151600 BLAKE2B c706767917e9ba3368f9670a492a2233b6a4c13c4dde6a594a06193d856b3fbad007988acb27486b8b8f62edfeb5a0b030ead3db712baa24b0ff3301cf776937 SHA512 b14d29dff4f7791d9223d20b490f4a48ba5a6a7613dc18fc3083a3b6bf810f9a42fcac94bfe72f92023802fc8c1fe0e6432d491af2f274a138ddc56db5550ea5

diff --git a/dev-python/pyspelling/pyspelling-2.10.ebuild b/dev-python/pyspelling/pyspelling-2.10.ebuild
new file mode 100644
index 000000000000..15d322559263
--- /dev/null
+++ b/dev-python/pyspelling/pyspelling-2.10.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=hatchling
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	>=dev-python/mkdocs-pymdownx-material-extras-2.1
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-minify-plugin
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Spell checker automation tool"
+HOMEPAGE="
+	https://github.com/facelessuser/pyspelling/
+	https://pypi.org/project/pyspelling/
+"
+SRC_URI="
+	https://github.com/facelessuser/pyspelling/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	|| ( app-text/aspell app-text/hunspell )
+
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/soupsieve-1.8[${PYTHON_USEDEP}]
+	>=dev-python/wcmatch-6.5[${PYTHON_USEDEP}]
+"
+# The package can use either aspell or hunspell but tests both if both
+# are installed.  Therefore, we need to ensure that both have English
+# dictionary installed.
+BDEPEND="
+	test? (
+		app-dicts/aspell-en
+		app-dicts/myspell-en
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# mkdocs-git-revision-date-localized-plugin needs git repo
+	if use doc; then
+		git init -q || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -q -m 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}