[gentoo-commits] repo/gentoo:master commit in: dev-lang/fuzion/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     aef0824d5312c055a25f98a5f0dfbefad9a03863
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 12 21:24:10 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Fri Jan 12 23:21:59 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aef0824d

dev-lang/fuzion: bump to 0.086

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-lang/fuzion/Manifest            |  1 +
 dev-lang/fuzion/fuzion-0.086.ebuild | 73 +++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-lang/fuzion/Manifest b/dev-lang/fuzion/Manifest
index 50c58d72012c..7fa40b129abd 100644
--- a/dev-lang/fuzion/Manifest
+++ b/dev-lang/fuzion/Manifest
@@ -1 +1,2 @@
 DIST fuzion-0.085.tar.gz 951247 BLAKE2B 5ae8999453759e0a8e5fb44b0aec833adb2c66ca9fea3e3092e2f298cc27a98c75abe0947337e9bb43920009d3bed8aa526a325fc58791d6177cb4f2d7ae7f23 SHA512 4a40eeffaa40b0568d90a20cf4125e7bddcc651fbe55b38866bb3cc90517749259336f776c33b762969986accae01e532b09418114b7c60e98377074bf144a17
+DIST fuzion-0.086.tar.gz 994894 BLAKE2B e698ea7b8de215c55e84e0f55f405156d5c386c1001c7b29e0c7c49e7a7e7babf7cb64cf30726a24aa7b6ccdc0eaf01cc543867361e2554f258d76be1fc08b97 SHA512 6d2df12d1dced9c5a61bb183767fc205ddbc0d04db8cae3f5e3eabd9ab60f18b3c2b3fa8f57702dc792882b1a6f79da1cfcb7801d84ecc2cff1844a4bc226f67

diff --git a/dev-lang/fuzion/fuzion-0.086.ebuild b/dev-lang/fuzion/fuzion-0.086.ebuild
new file mode 100644
index 000000000000..388f1e28729c
--- /dev/null
+++ b/dev-lang/fuzion/fuzion-0.086.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-pkg-2
+
+DESCRIPTION="A language with a focus on simplicity, safety and correctness"
+HOMEPAGE="https://flang.dev/
+	https://github.com/tokiwa-software/fuzion/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/tokiwa-software/${PN}.git"
+else
+	SRC_URI="https://github.com/tokiwa-software/${PN}/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=virtual/jre-17:*
+	dev-libs/boehm-gc
+"
+# jdk:17 for https://bugs.gentoo.org/916689
+DEPEND="
+	virtual/jdk:17
+"
+BDEPEND="
+	test? ( sys-devel/clang:* )
+"
+
+DOCS=( README.md release_notes.md )
+
+src_compile() {
+	emake -j1
+}
+
+src_test() {
+	emake -j1 run_tests_parallel
+}
+
+src_install() {
+	# Remove unnecessary files from build directory. bug #893450
+	local torm
+	local torm_path
+	for torm in tests run_tests.{failures,results} ; do
+		torm_path="${S}/build/${torm}"
+
+		if [[ -e "${torm_path}" ]] ; then
+			rm -r "${torm_path}" || die "failed to remove ${torm_path}"
+		fi
+	done
+
+	insinto "/usr/share/${PN}"
+	doins -r build/.
+	insopts -m755
+	doins -r build/bin
+
+	local bin
+	for bin in fz fzjava ; do
+		dosym -r "/usr/share/${PN}/bin/${bin}" "/usr/bin/${bin}"
+	done
+
+	einstalldocs
+}