[gentoo-commits] proj/kde:master commit in: kde-plasma/print-manager/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     c44ce8a0b196f5eb5ec54e39241429059d9b87ba
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 10 13:28:32 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan 10 16:46:19 2024 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=c44ce8a0

kde-plasma/print-manager: 5.92.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../print-manager/print-manager-5.92.0.ebuild      | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/kde-plasma/print-manager/print-manager-5.92.0.ebuild b/kde-plasma/print-manager/print-manager-5.92.0.ebuild
new file mode 100644
index 0000000000..b34f1a4875
--- /dev/null
+++ b/kde-plasma/print-manager/print-manager-5.92.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=9999
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.6.0
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Manage CUPS print jobs and printers in Plasma"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="+gtk"
+
+DEPEND="
+	dev-libs/kirigami-addons:6
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-plasma/libplasma-${PVCUT}:6
+	net-print/cups
+"
+RDEPEND="${DEPEND}
+	!<kde-plasma/print-manager-23.08.5-r100:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:6
+	kde-plasma/kde-cli-tools:*
+	gtk? ( app-admin/system-config-printer )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! use gtk ; then
+		ewarn "By switching off \"gtk\" USE flag, you have chosen to do without"
+		ewarn "an important, though optional, runtime dependency:"
+		ewarn
+		ewarn "app-admin/system-config-printer"
+		ewarn
+		ewarn "${PN} will work nevertheless, but is going to be less comfortable"
+		ewarn "and will show the following error status during runtime:"
+		ewarn
+		ewarn "\"Failed to group devices: 'The name org.fedoraproject.Config.Printing"
+		ewarn "was not provided by any .service files'\""
+	fi
+}