[gentoo-commits] repo/gentoo:master commit in: dev-python/pyatspi/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     2c808dd133ea851a2c609b96600f23a0d0433d18
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Jan  6 19:17:52 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Jan  6 19:18:00 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2c808dd1

dev-python/pyatspi: add 2.46.1, enable python3_12

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-python/pyatspi/Manifest              |  1 +
 dev-python/pyatspi/pyatspi-2.46.1.ebuild | 61 ++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/pyatspi/Manifest b/dev-python/pyatspi/Manifest
index 29f234a82ccb..460c308ab92e 100644
--- a/dev-python/pyatspi/Manifest
+++ b/dev-python/pyatspi/Manifest
@@ -1 +1,2 @@
 DIST pyatspi-2.46.0.tar.xz 324112 BLAKE2B 653e80be2d17f3246bb6bb60c2135f158185374c995ca37d4f132c90d0bf02b79cfcbc4f64d555c557e9f7fd1cf0720de2c5d177b303e35a84d8e4490ae2e660 SHA512 4e9d177c930db3ccb5aa41280e33a58b6700d9c45f08b6a2f32fce0ecf5f1faa3f91c57281a5661bb9ccaafd0935e90b44f328a62988ae838b4a008916d2aa0f
+DIST pyatspi-2.46.1.tar.xz 323392 BLAKE2B ee55f57616d58ead8bbf14193a984e2d268b0dafd67bdb638086fe531d7d031b6060f2c757036f67ad18ba6c1f774c8ef13a4844c5fb96878604f59903b2653a SHA512 69c1c4c31bef430083a1c9af98ba6b2f1b3d9eec0a5f03982b980838bcf86933069a90d7314d2e5501d5988a453d0a803ad239eca5b98f08cc3bf7dc8d4a7c0c

diff --git a/dev-python/pyatspi/pyatspi-2.46.1.ebuild b/dev-python/pyatspi/pyatspi-2.46.1.ebuild
new file mode 100644
index 000000000000..c95ed5df7428
--- /dev/null
+++ b/dev-python/pyatspi/pyatspi-2.46.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Python client bindings for D-Bus AT-SPI"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-2.34[introspection]
+"
+BDEPEND="virtual/pkgconfig
+	test? ( x11-libs/gtk+:3 )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure $(use_enable test tests)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir dbus-run-session emake check
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installing
+
+	docinto examples
+	dodoc examples/*.py
+}