[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     bf853aa88474bc89893e1cb78cb3daca528c84df
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  3 06:39:46 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan  3 08:29:53 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf853aa8

dev-python/django: Bump to 4.2.9

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |   2 +
 dev-python/django/django-4.2.9.ebuild | 100 ++++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index e780bf445360..503434beed15 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,6 +4,8 @@ DIST Django-4.1.12.checksum.txt 2582 BLAKE2B 67b101ef7b11fe1ad47872b9bbb26851b20
 DIST Django-4.1.12.tar.gz 10502350 BLAKE2B 1e13d4a7c00d7fa49c41bbdc3e69604e462de9ebdb302097ca610cd7d791ebb1ac4bdb610b791e7d578125df83be0551b5d98fbeace630a042a8101689cb9d56 SHA512 63211a82f55b8c7ef0d8f9d09bfba926c2dc59ab7bacded517c4c3014c671ed55d0d5552678d1eae350d3d66f27dde96aed0a5e2aa1ae5f6e1c98ccf138ccc1d
 DIST Django-4.2.8.checksum.txt 2553 BLAKE2B 552fd9dc6740baabc434a4d069c0a22c49e36661da58face4853c8ca5f34254314a3ca85048d5a4786a9a15ed27c8f73016c9a3d7bcf63dc617373e243a3ee77 SHA512 e3808f5d28fb95aa6ebbcc393161cc69cb948ab4ebe0dcc7a4f6ca8964e4a3dacf4aa185688d21b5d176456621f609e95909cbbc4abe6528f72afe3b644b5ea3
 DIST Django-4.2.8.tar.gz 10425581 BLAKE2B e3592dadb54a616cea6129ba45f27e1c93dda2fcffec8c827e2f74a46c6c953a6c2893f236eff64dc77106ee60246eb843e028d44ebf27b8e30da1a6f766315f SHA512 9a60d2202886656a239e764c79b3638d4bc9e549bba8a822b36c745ab32468e3ddd813e7cda4a9e69c867ede0fca02da63391a2efe1462798e5c2e4f35625b63
+DIST Django-4.2.9.checksum.txt 2552 BLAKE2B 9b7fe091d450ee1a9c2b9beb73afbb3b79c8b5a5d474d8908c6fde5aa0a9e90e78259716daf79c98449dff6e263bb953fad11b9e78b7d3b7db62ea5a58c64942 SHA512 aa26b2870a2582d3627224fab7a698cc32e4734b7e2b9e6bda6a0b35484f786619a386f2027319a3ec648cbbeab1b2982e130e2b05ac02a0b99623d89b56d681
+DIST Django-4.2.9.tar.gz 10428500 BLAKE2B a8c42ed18fc95cd0a92319371e342b165ce5fa7ed6db428e5f2020c1a3d0611413425da82cb38c39b6c65379a66e44b955d8b3aa164d8f7924df342275f3660c SHA512 15516e80718aff6bda322fa62124dfa0b277983318cd3e47e87d74f68e8e913403b41d6213010a665e8edc4f46f0f42411f54e878bf77c8f6090d515b8422406
 DIST Django-5.0.checksum.txt 2553 BLAKE2B 93202aa273f62a828b05ae9b34e7e96dd74ef5b852a94953fbd24e9a609609bf23fa73eaa005d4c9da48dba508bf2efe6a21e91096fee90b1f6811c0af6d4843 SHA512 eb44a3a4128188fd4dd90c6e7b0202652c64db8572daa72e617cf0464b2278cc7839562b880158264bbebc24efe871c3b376c3c134a5c7033292f2b765d6f3b0
 DIST Django-5.0.tar.gz 10585390 BLAKE2B 50cc715e21b046292dd86c08801b6f182c8e71a36c73de657ca631b611738e196ab6d4fa035589c26fff952170fb92e0a752a8af15771c33107e343b01d7b4d7 SHA512 d0591eb109cecffd330138ef63c7f768a77b6763ce73a5bc656d892181613981094221e2f77d5888ba4679b581df21ec8e6ac5faa67d31d00d289f4d892caf2f
 DIST django-4.2.8-pypy3.patch.xz 5900 BLAKE2B b7dc5c5fc162817a218ee6d025ed8a65559b80e4506e49ac393428c26e2621f9e7c5010b36f2412dea8194a9f1086ab21f97286eabd696c6a786285eb07393cf SHA512 f953b5adbd1364f1d84dde55087ccb493256b1327701275fd2fe99f3cd41751d18e002b6e21afc96892e1671428a6b8f3c2e4b88252c3c278f1a79e286bb73e3

diff --git a/dev-python/django/django-4.2.9.ebuild b/dev-python/django/django-4.2.9.ebuild
new file mode 100644
index 000000000000..927c7bb1f192
--- /dev/null
+++ b/dev-python/django/django-4.2.9.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/python/django-4.2.8-pypy3.patch.xz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20230606 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/django-4.0-bashcomp.patch
+	"${WORKDIR}"/django-4.2.8-pypy3.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+		-v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:0
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}