[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     0615b47b678cf5deac9600facfdcf9d02c0d72bd
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 22 20:37:26 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Dec 23 18:29:40 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0615b47b

kde-plasma/plasma-firewall: 5.91.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.91.0.ebuild  | 60 ++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index c2170d01dfee..56cb143e36e6 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.27.10.tar.xz 363288 BLAKE2B abebad4476e270ec5da39a4a8791382fe287d058e0e8bd2fe381204300cf41213adaa8125ca1c585d457ab969beadcd6122119798ae6c8bda0ad6660d2d14217 SHA512 350d44e26b6a9100b3f6ac9022b2e653f2ff55ec62f8efbef7b747eac006d8a0eb7182f8161a587cafadc07d5126fc0ea439e0624e578911ddba718fc99856d4
 DIST plasma-firewall-5.27.9.tar.xz 363280 BLAKE2B 519e9e21aba5d779733320d4a1ab4b71a71c2b6a032c4274f99b84a8e22329b912b67f492b2cc6782ae5a185a578247ae7d5a9364a2ab3e527b0ce7400a8addb SHA512 e58f27f4823f5c01d1f447018c43cc36bdbe8055f3cade667539a09e12dc4e73b9051f104a0a5e904846ae1dabc611006276eba68462fd19d7769f5d79803734
+DIST plasma-firewall-5.91.0.tar.xz 367624 BLAKE2B e8129c2cc0ca574466884701deb89b0f0e1cfd28e4102c3fe0c3f6715365066ddad5dff0a672431bd946b88026098189bee419c6aef6dda3c8dbf29f0383616a SHA512 415f47425b458e91672c72c128d8b032b111a65b07beb9a3b9e65f4513878aa47c339886bef58bc19132d417cea141c8d80bb8014fd2aff16c197082d33e873f

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.91.0.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.91.0.ebuild
new file mode 100644
index 000000000000..6db57aa6f86b
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.91.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{10..12} )
+KFMIN=5.247.0
+QTMIN=6.6.0
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}