[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-welcome/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     92dc69299dfbd60fc561f08b8a7beafaf712f556
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 20 16:40:33 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Dec 20 23:01:10 2023 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=92dc6929

kde-plasma/plasma-welcome: 5.91.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../plasma-welcome/plasma-welcome-5.91.0.ebuild    | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/kde-plasma/plasma-welcome/plasma-welcome-5.91.0.ebuild b/kde-plasma/plasma-welcome/plasma-welcome-5.91.0.ebuild
new file mode 100644
index 0000000000..5cf50e126c
--- /dev/null
+++ b/kde-plasma/plasma-welcome/plasma-welcome-5.91.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.247.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.6.0
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Friendly onboarding wizard for Plasma"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="discover telemetry"
+
+DEPEND="
+	dev-libs/kirigami-addons:6
+	>=dev-qt/qtbase-${QTMIN}:6[gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ksvg-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-plasma/libplasma-${PVCUT}:6
+	telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qt5compat-${QTMIN}:6[qml]
+	discover? ( kde-plasma/discover:6 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	if ! use discover; then
+		sed -e "s:pageStack.push(discover);:// & disabled by IUSE=discover:" \
+			-i src/contents/ui/Main.qml || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package telemetry KF6UserFeedback)
+	)
+	ecm_src_configure
+}