From: "Andrew Ammerlaan" <andrewammerlaan@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/
Date: Tue, 19 Dec 2023 10:35:19 +0000 (UTC) [thread overview]
Message-ID: <1702982109.fde0be16adf71239c88e4d6d70b35becb3997d5e.andrewammerlaan@gentoo> (raw)
commit: fde0be16adf71239c88e4d6d70b35becb3997d5e
Author: Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 19 10:34:33 2023 +0000
Commit: Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Tue Dec 19 10:35:09 2023 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fde0be16
dev-python/spyder: add 6.0.0_alpha3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>
dev-python/spyder/Manifest | 1 +
dev-python/spyder/spyder-6.0.0_alpha3.ebuild | 189 +++++++++++++++++++++++++++
2 files changed, 190 insertions(+)
diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 76d9c1af467e..473bbb268d82 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -2,5 +2,6 @@ DIST spyder-5.4.4.gh.tar.gz 16214815 BLAKE2B 43bdf54599acc9c7ecf38d25a2d18e46347
DIST spyder-5.4.5.gh.tar.gz 16214117 BLAKE2B e572fe2e104e464bacff939c6195d1042c6ff0e6a1167c3ab4bf96a4f7dde0a1abb6ec84dc0dd54af24cd1635ecf8b80dabcc43c5131821bb3f7f6f08300605f SHA512 d938e3e64c22837bd4a7ab55822e9d763842cadba3cfb3de952652164054a4b87c2495bd8ae2617dbdd8bad5120e84e9017269d4bcdd6cbf73fb3d4dddbcad8f
DIST spyder-5.5.0.gh.tar.gz 16251845 BLAKE2B 8a8ea4a7da30d79b91e9a20a904e88a21517d99d51b29535ba250c3d0a970a5e00eb8f43a3e9b00eeef457823baf553d0694c3ef57ca798fe002d1d0fdf2f4d7 SHA512 6be7b80a99996beae2542a0646b54a665a89d09929634b21ddcb67f61584fa7f53e9f921fc8d2a4edf6c8ee5e98db0d8423a52a8b93b8ed58b9f46d062ecfeac
DIST spyder-6.0.0_alpha2.gh.tar.gz 16311030 BLAKE2B 17466525aea0afa93ce0efd2cba3e249d6e95e458fdbe35ed672e704b3643fe17adbc663498436bb6cf435a6ab9f704f435ed014eec8a695eaf558dd17ac5785 SHA512 9a80954e18a0b4cf3f2a0ad20ee39cfda867ed1df0b2dc3f2ddbcd78cff09064accf3b9089ce1076dcdc8fe52a6af04c10b22b9d123d7353bfdc789c470d7cc9
+DIST spyder-6.0.0_alpha3.gh.tar.gz 15480385 BLAKE2B 5e41a7765ce7e4d0ac0148f07601b098a60e200c90d89aeda89272c9f29521abcca1fb152dec09bbf23261cfef302c5c504ba6733fa0a690163d3081a7c19216 SHA512 c8ed1caaf9ef2d8cbae351825463d6a7a549efd2b072a0bbb24ae85745132cae4fadfd92d8219dc031ba1b775dc413a596e0c5725604aee40757cac1096825e9
DIST spyder-docs-0aa81d44ec6490c155be1bb1acca0a27328b12e0.gh.tar.gz 94895731 BLAKE2B 468412372bf2f70f838fa89dc1b88997fa2d9d92e36d6a5abac736b6b5f2782f25121b18b876c7c6e2af9d7eda433aaccd017c2e8c8c06a223420f0ce9684fc1 SHA512 9ac0f930a1a864e81e4181f101449a6506728d0d89254409a58e68bc17a3de39f4d1bf329f11da433d8ee4f3122faf3b337654d011263a70b253459e9562e923
DIST spyder-docs-cfa8e009264cb5e79beeead6a012e521db2c73dc.gh.tar.gz 94895763 BLAKE2B b26a8f834db25fd2a8881fdd411329a6d70213827d450070d4f73692742764efb34c74c6dd72d51829b8718956a4def172eaba56a1f02c264552aa838860feb9 SHA512 67defa7913392b0c41a931badb1f5669adcaf8d27e2d3ef59c5d07810c4423272776f369ab134b5096209d781009bbf076711f780234ec93fbe3e1a52e475dcd
diff --git a/dev-python/spyder/spyder-6.0.0_alpha3.ebuild b/dev-python/spyder/spyder-6.0.0_alpha3.ebuild
new file mode 100644
index 000000000000..2033578ed6f6
--- /dev/null
+++ b/dev-python/spyder/spyder-6.0.0_alpha3.ebuild
@@ -0,0 +1,189 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature virtualx xdg
+
+# Commit of documentation to fetch
+DOCS_PV="0aa81d44ec6490c155be1bb1acca0a27328b12e0"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+ https://www.spyder-ide.org/
+ https://github.com/spyder-ide/spyder/
+ https://pypi.org/project/spyder/
+"
+SRC_URI="
+ https://github.com/spyder-ide/${PN}/archive/v${PV//_alpha/a}.tar.gz -> ${P}.gh.tar.gz
+ https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
+"
+S="${WORKDIR}/${PN}-${PV//_alpha/a}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+
+RDEPEND="
+ >=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+ >=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+ >=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+ >=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+ >=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+ >=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+ >=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+ >=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+ >=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+ >=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+ >=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+ >=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+ >=dev-python/pylint-venv-3.0.2[${PYTHON_USEDEP}]
+ >=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}]
+ >=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+ >=dev-python/pyuca-1.2[${PYTHON_USEDEP}]
+ >=dev-python/qdarkstyle-3.2.0[${PYTHON_USEDEP}]
+ <dev-python/qdarkstyle-3.3.0[${PYTHON_USEDEP}]
+ >=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
+ >=dev-python/qtawesome-1.3.0[${PYTHON_USEDEP}]
+ >=dev-python/qtconsole-5.5.0[${PYTHON_USEDEP}]
+ <dev-python/qtconsole-5.6.0[${PYTHON_USEDEP}]
+ >=dev-python/QtPy-2.4.0[${PYTHON_USEDEP},svg,webengine]
+ >=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+ >=dev-python/spyder-kernels-3.0.0_beta3[${PYTHON_USEDEP}]
+ <dev-python/spyder-kernels-3.0.0_beta4[${PYTHON_USEDEP}]
+ >=dev-python/superqt-0.6.1[${PYTHON_USEDEP}]
+ <dev-python/superqt-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+ >=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+ >=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+ test? (
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/flaky[${PYTHON_USEDEP}]
+ dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+ dev-python/pandas[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/pytest-order[${PYTHON_USEDEP}]
+ dev-python/pytest-qt[${PYTHON_USEDEP}]
+ dev-python/pytest-timeout[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/QtPy[${PYTHON_USEDEP},pyside2,pyqt5]
+ dev-python/scipy[${PYTHON_USEDEP}]
+ dev-python/sympy[${PYTHON_USEDEP}]
+ )"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+ "${FILESDIR}/${PN}-5.0.0-build.patch"
+ "${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
+)
+
+DOCS=(
+ "AUTHORS.txt"
+ "Announcements.md"
+ "CHANGELOG.md"
+ "CODE_OF_CONDUCT.md"
+ "CONTRIBUTING.md"
+ "NOTICE.txt"
+ "README.md"
+ "RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc \
+ dev-python/sphinx-panels \
+ dev-python/pydata-sphinx-theme \
+ dev-python/sphinx-multiversion
+
+python_prepare_all() {
+ # move docs into workdir
+ mv ../spyder-docs-${DOCS_PV}* docs || die
+
+ # these dependencies are packaged separately:
+ # dev-python/spyder-kernels,
+ # dev-python/python-lsp-server,
+ # dev-python/qdarkstyle
+ rm -r external-deps/* || die
+ # runs against things packaged in external-deps dir
+ rm conftest.py || die
+
+ # Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
+ # Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
+ # Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+ # Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+ # Do not depend on ipython, this dependency is carried in spyder-kernels
+ # The explicit version requirements only make things more complicated, if e.g.
+ # pyls-spyder gains compatibility with a newer version of python-lsp-server
+ # in a new release it will take time for this information to propagate into
+ # the next spyder release. So just remove the dependency and let the other
+ # ebuilds handle the version requirements to speed things up and prevent
+ # issues such as Bug 803269.
+ sed -i \
+ -e "/'pyqt5[ 0-9<=>.,]*',/d" \
+ -e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+ -e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+ -e "/'parso[ 0-9<=>.,]*',/d" \
+ -e "/'jedi[ 0-9<=>.,]*',/d" \
+ -e "/'pylint[ 0-9<=>.,]*',/d" \
+ setup.py || die
+ # -e "/'ipython[ 0-9<=>.,]*',/d" \
+ sed -i \
+ -e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+ -e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+ -e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+ -e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+ -e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+ spyder/dependencies.py || die
+ # -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
+
+ # do not check deps, fails because we removed dependencies above
+ sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+ spyder/tests/test_dependencies_in_sync.py || die
+
+ # skip online test
+ rm spyder/widgets/github/tests/test_github_backend.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly somehow passes the pytest arguments to spyder
+# causing an invalid argument error
+python_test() {
+ virtx "${EPYTHON}" runtests.py
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+ optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+ optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+ optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+ optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+ optfeature "Run Cython files in the IPython console" dev-python/cython
+ optfeature "The hdf5/h5py plugin" dev-python/h5py
+ optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+ optfeature "Vim key bindings" dev-python/spyder-vim
+ optfeature "Unittest support" dev-python/spyder-unittest
+ optfeature "System terminal inside spyder" dev-python/spyder-terminal
+ optfeature "Jupyter notebook support" dev-python/spyder-notebook
+ # spyder-memory-profiler is not compatible with spyder-5.2+ yet
+ # optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+ # spyder-reports not yet updated to >=spyder-4.0.0
+ # optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+ # Plugins with no release yet:
+ # optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
+ # optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
+}
next reply other threads:[~2023-12-19 10:35 UTC|newest]
Thread overview: 141+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-12-19 10:35 Andrew Ammerlaan [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-03-27 11:47 [gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/ Nowa Ammerlaan
2025-02-19 20:22 Michał Górny
2025-02-07 14:57 Nowa Ammerlaan
2025-01-23 17:31 Arthur Zamarin
2025-01-02 15:20 Nowa Ammerlaan
2024-12-20 16:09 Nowa Ammerlaan
2024-12-20 16:09 Nowa Ammerlaan
2024-11-23 11:36 Andreas Sturmlechner
2024-11-01 10:02 Andrew Ammerlaan
2024-09-24 8:40 Andrew Ammerlaan
2024-09-24 8:40 Andrew Ammerlaan
2024-09-10 9:31 Andrew Ammerlaan
2024-09-03 7:55 Andrew Ammerlaan
2024-09-03 7:55 Andrew Ammerlaan
2024-08-27 7:36 Andrew Ammerlaan
2024-08-24 19:24 Andrew Ammerlaan
2024-08-24 19:24 Andrew Ammerlaan
2024-08-10 8:45 Andrew Ammerlaan
2024-08-10 8:45 Andrew Ammerlaan
2024-07-20 11:59 Andrew Ammerlaan
2024-07-20 11:59 Andrew Ammerlaan
2024-06-19 11:00 Andrew Ammerlaan
2024-06-19 11:00 Andrew Ammerlaan
2024-06-12 10:20 Andrew Ammerlaan
2024-05-17 14:13 Andrew Ammerlaan
2024-05-17 14:13 Andrew Ammerlaan
2024-04-24 12:47 Andrew Ammerlaan
2024-04-24 12:47 Andrew Ammerlaan
2024-04-10 8:08 Andrew Ammerlaan
2024-04-10 8:08 Andrew Ammerlaan
2024-03-18 8:22 Andrew Ammerlaan
2024-03-18 8:22 Andrew Ammerlaan
2024-03-13 8:42 Andrew Ammerlaan
2024-03-03 18:58 Andrew Ammerlaan
2024-02-26 14:25 Michał Górny
2024-02-08 13:37 Andrew Ammerlaan
2024-02-08 13:37 Andrew Ammerlaan
2024-02-07 9:59 Andrew Ammerlaan
2023-12-30 18:35 Michał Górny
2023-12-29 13:42 Arthur Zamarin
2023-12-19 10:35 Andrew Ammerlaan
2023-11-11 9:26 Andrew Ammerlaan
2023-11-08 9:35 Andrew Ammerlaan
2023-09-07 15:43 Andrew Ammerlaan
2023-09-07 15:43 Andrew Ammerlaan
2023-08-30 7:51 Andrew Ammerlaan
2023-07-24 11:34 Michał Górny
2023-07-19 9:40 Andrew Ammerlaan
2023-06-20 18:40 Andrew Ammerlaan
2023-04-07 8:22 Andrew Ammerlaan
2023-04-05 19:23 Andrew Ammerlaan
2023-01-27 20:10 Michał Górny
2023-01-19 7:39 Andrew Ammerlaan
2023-01-12 11:13 Andrew Ammerlaan
2022-12-30 11:47 Andrew Ammerlaan
2022-11-07 21:53 Andrew Ammerlaan
2022-09-05 12:34 Andrew Ammerlaan
2022-09-05 12:34 Andrew Ammerlaan
2022-08-30 17:32 Andrew Ammerlaan
2022-08-30 17:32 Andrew Ammerlaan
2022-07-19 18:44 Andrew Ammerlaan
2022-06-01 11:49 Andrew Ammerlaan
2022-05-25 9:43 Andrew Ammerlaan
2022-05-23 17:55 Andrew Ammerlaan
2022-05-23 17:55 Andrew Ammerlaan
2022-05-11 9:41 Andrew Ammerlaan
2022-05-11 9:41 Andrew Ammerlaan
2022-03-31 14:31 Andrew Ammerlaan
2022-01-23 10:52 Andrew Ammerlaan
2022-01-21 19:22 Andrew Ammerlaan
2022-01-21 19:22 Andrew Ammerlaan
2021-12-15 17:12 Andrew Ammerlaan
2021-12-14 17:18 Andrew Ammerlaan
2021-12-14 17:18 Andrew Ammerlaan
2021-11-06 16:24 Andrew Ammerlaan
2021-11-06 16:20 Andrew Ammerlaan
2021-10-04 8:33 Andrew Ammerlaan
2021-09-27 19:28 Andrew Ammerlaan
2021-09-16 17:49 Andrew Ammerlaan
2021-09-16 17:49 Andrew Ammerlaan
2021-09-13 7:31 Andrew Ammerlaan
2021-09-13 7:31 Andrew Ammerlaan
2021-09-05 9:54 Andrew Ammerlaan
2021-09-05 9:54 Andrew Ammerlaan
2021-09-02 6:33 Andrew Ammerlaan
2021-09-02 6:33 Andrew Ammerlaan
2021-08-05 7:45 Andrew Ammerlaan
2021-08-05 7:45 Andrew Ammerlaan
2021-08-02 8:20 Andrew Ammerlaan
2021-07-23 13:49 Andrew Ammerlaan
2021-07-02 11:49 Andrew Ammerlaan
2021-06-23 20:12 Andrew Ammerlaan
2021-06-23 20:12 Andrew Ammerlaan
2021-06-12 10:25 Andrew Ammerlaan
2021-06-11 18:31 Andrew Ammerlaan
2021-06-11 18:31 Andrew Ammerlaan
2021-06-05 10:47 Andrew Ammerlaan
2021-05-22 9:11 Andrew Ammerlaan
2021-05-20 11:57 Andrew Ammerlaan
2021-05-19 18:42 Andrew Ammerlaan
2021-05-19 18:42 Andrew Ammerlaan
2021-04-16 9:55 Joonas Niilola
2021-03-25 13:58 Joonas Niilola
2021-03-25 13:58 Joonas Niilola
2021-03-21 13:35 Joonas Niilola
2021-03-20 10:46 Joonas Niilola
2021-03-20 10:46 Joonas Niilola
2021-03-11 7:18 Joonas Niilola
2020-11-17 16:30 Joonas Niilola
2020-11-17 14:21 Joonas Niilola
2020-11-17 14:21 Joonas Niilola
2020-11-17 14:21 Joonas Niilola
2020-11-17 14:21 Joonas Niilola
2020-09-18 15:53 Michał Górny
2020-09-15 8:09 Joonas Niilola
2020-08-20 6:37 Andrey Grozin
2020-07-17 4:14 Matt Turner
2020-05-26 20:43 Matt Turner
2020-03-30 11:27 Joonas Niilola
2020-03-30 11:27 Joonas Niilola
2020-03-28 14:21 Joonas Niilola
2020-02-28 16:12 Andrey Grozin
2020-02-19 7:34 Joonas Niilola
2019-12-04 17:15 Michał Górny
2019-12-04 17:15 Michał Górny
2019-11-17 21:12 Davide Pesavento
2019-05-05 7:15 Michał Górny
2018-09-25 10:19 Andrey Grozin
2018-04-29 7:35 Michał Górny
2017-09-24 10:28 Andrey Grozin
2017-09-19 11:57 Andrey Grozin
2017-09-19 11:55 Andrey Grozin
2017-08-15 20:10 Andreas Sturmlechner
2017-08-15 20:10 Andreas Sturmlechner
2017-08-15 20:10 Andreas Sturmlechner
2016-12-18 4:47 Andrey Grozin
2016-02-23 11:15 Andrey Grozin
2016-02-23 9:28 Patrice Clement
2016-02-23 9:28 Patrice Clement
2016-02-23 8:20 Patrice Clement
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1702982109.fde0be16adf71239c88e4d6d70b35becb3997d5e.andrewammerlaan@gentoo \
--to=andrewammerlaan@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox