[gentoo-commits] repo/gentoo:master commit in: gnome-base/nautilus/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     cdd32b85779e7f27cb7f43a6e28df2334d32f73a
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sun Dec  3 21:41:11 2023 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Mon Dec 18 10:19:11 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cdd32b85

gnome-base/nautilus: Version bump to 45.2.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/34120
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-base/nautilus/Manifest               |   1 +
 gnome-base/nautilus/nautilus-45.2.1.ebuild | 123 +++++++++++++++++++++++++++++
 2 files changed, 124 insertions(+)

diff --git a/gnome-base/nautilus/Manifest b/gnome-base/nautilus/Manifest
index c054886f3356..835a907690a7 100644
--- a/gnome-base/nautilus/Manifest
+++ b/gnome-base/nautilus/Manifest
@@ -1,3 +1,4 @@
 DIST nautilus-44.2.1.tar.xz 3190824 BLAKE2B 159abd8fbaea3f372febb4c7f68f95d97b50ac19e31d6108c9588aa849f92ea82a2a04402c8ee78f223339ffe929ed3fc95e4606db7753adacf6edb49f340910 SHA512 35974f9d2d785c69d4199287f1b79aa83397b37b3ad3ebe97894ee5e5d9aa4a981808fa443d5c04d2c7223c290a2cad87e3eeb62787b1d241486c39d5e061769
 DIST nautilus-45.0.tar.xz 3212952 BLAKE2B 38a6e572d6ce41515bb2447bf5636c82b28f0b1fe16b56540910a7c69fb2ce45495ad128d1bd969665749244f2a45e055b22e4c4d5815afc921afe8862776240 SHA512 046c2afac51dc42337a1f26cbbb76cbbdc7145999b46574efc02acac5d0bc1ebeb8d84fa4121973216ee49f8a2cc102b62e72eeabc4141c48046cf7685789f64
 DIST nautilus-45.1.tar.xz 3207896 BLAKE2B 3d487deed19aaa79302a94f5205c172b6ba3fd739d495f235a9f6dafb42a68ac54e88228ed422932b15deb2fcb4bf2c5730e8a528221ee70f86eb9deb7c3a96c SHA512 ae3a21891d28c85976015eee1d605cb43b5d9c23da74ac2635cc65435f922bbad01d1b6eaa7ea4893121e08005c49f9ef9f2bbc217b9525a2f432d99636b3ffd
+DIST nautilus-45.2.1.tar.xz 3208272 BLAKE2B 80adf7ace00c21d21eddf764595c3f981e6206b936996458e5c2cc9cc51536e759528bdc38d1cddfe1c87eb94eac0ef2ced714ae797db947b81199a4bfa41c9d SHA512 c1e26e9f802f62ccb7a7d60f895575a1b31d8071f6a60206472fe79f70d64717b9abe97a5c5c0c87349994ff6f144dfe97c7bd448a05a9da00ff9918884e65fa

diff --git a/gnome-base/nautilus/nautilus-45.2.1.ebuild b/gnome-base/nautilus/nautilus-45.2.1.ebuild
new file mode 100644
index 000000000000..5a07549431d0
--- /dev/null
+++ b/gnome-base/nautilus/nautilus-45.2.1.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="Default file manager for the GNOME desktop"
+HOMEPAGE="https://apps.gnome.org/Nautilus/"
+
+LICENSE="GPL-3+ LGPL-2.1+"
+SLOT="0"
+IUSE="+cloudproviders gnome +gstreamer gtk-doc +introspection +previewer selinux sendto"
+REQUIRED_USE="gtk-doc? ( introspection )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.77.0:2
+	>=media-libs/gexiv2-0.14.2
+	>=x11-libs/gdk-pixbuf-2.30.0:2
+	gstreamer? ( media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0 )
+	>=app-arch/gnome-autoar-0.4.4
+	>=gnome-base/gnome-desktop-43:4=
+	>=gnome-base/gsettings-desktop-schemas-42
+	>=gui-libs/gtk-4.11.2:4[introspection?]
+	>=gui-libs/libadwaita-1.4_alpha:1
+	>=dev-libs/libportal-0.5:=[gtk]
+	>=x11-libs/pango-1.28.3
+	selinux? ( >=sys-libs/libselinux-2.0 )
+	>=app-misc/tracker-3.0:3
+	>=dev-libs/libxml2-2.7.8:2
+	cloudproviders? ( >=net-libs/libcloudproviders-0.3.1 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	>=app-misc/tracker-miners-3.0:3=
+" # uses org.freedesktop.Tracker.Miner.Files gsettings schema from tracker-miners
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.51.2
+	dev-util/glib-utils
+	gtk-doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		dev-util/gi-docgen
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( sys-apps/dbus )
+"
+PDEPEND="
+	gnome? ( x11-themes/adwaita-icon-theme )
+	previewer? ( >=gnome-extra/sushi-0.1.9 )
+	sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
+	>=gnome-base/gvfs-1.14[gtk(+)]
+" # Need gvfs[gtk] for recent:/// support; always built (without USE=gtk) since gvfs-1.34
+
+PATCHES=(
+	"${FILESDIR}"/43.0-optional-gstreamer.patch # Allow controlling audio-video-properties build
+)
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	# Disable -Werror
+	sed -e '/-Werror=/d' -i meson.build ||  die
+
+	if use previewer; then
+		DOC_CONTENTS="nautilus uses gnome-extra/sushi to preview media files.
+			To activate the previewer, select a file and press space; to
+			close the previewer, press space again."
+	fi
+
+	# Disable test-nautilus-search-engine-tracker; bug #831170
+	sed -e '/^tracker_tests = /{n;N;N;d}' -i test/automated/displayless/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dextensions=true # image file properties, sendto support; also required for -Dgstreamer=true
+		$(meson_use introspection)
+		-Dpackagekit=false
+		$(meson_use selinux)
+		$(meson_use cloudproviders)
+		-Dprofiling=false
+		-Dtests=$(usex test all none)
+
+		$(meson_use gstreamer) # gstreamer audio-video-properties extension
+	)
+	meson_src_configure
+}
+
+src_install() {
+	use previewer && readme.gentoo_create_doc
+	meson_src_install
+}
+
+src_test() {
+	# Avoid dconf that looks at XDG_DATA_DIRS, which can sandbox fail if flatpak is installed
+	gnome2_environment_reset
+	# TODO: Tests require tracker testutils (e.g. tracker-sandbox), which may
+	# need some sorting out with tracker use flag deps
+	# GIO_USE_VOLUME_MONITOR=unix due to https://gitlab.gnome.org/GNOME/gvfs/-/issues/629#note_1467280
+	GIO_USE_VOLUME_MONITOR=unix XDG_SESSION_TYPE=x11 virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if use previewer; then
+		readme.gentoo_print_elog
+	else
+		elog "To preview media files, emerge nautilus with USE=previewer"
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}