From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1579322-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (2048 bits) server-digest SHA256)
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id E715E158013
	for <garchives@archives.gentoo.org>; Wed, 13 Dec 2023 17:39:06 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 23A422BC018;
	Wed, 13 Dec 2023 17:39:06 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 05D402BC018
	for <gentoo-commits@lists.gentoo.org>; Wed, 13 Dec 2023 17:39:06 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 33892335DC0
	for <gentoo-commits@lists.gentoo.org>; Wed, 13 Dec 2023 17:39:05 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 63257ACA
	for <gentoo-commits@lists.gentoo.org>; Wed, 13 Dec 2023 17:39:03 +0000 (UTC)
From: "Patrick McLean" <chutzpah@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Patrick McLean" <chutzpah@gentoo.org>
Message-ID: <1702489117.1d6d2fa525e4b13476195b1d930dc523c88263df.chutzpah@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-admin/salt/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-admin/salt/Manifest app-admin/salt/salt-3006.5.ebuild
X-VCS-Directories: app-admin/salt/
X-VCS-Committer: chutzpah
X-VCS-Committer-Name: Patrick McLean
X-VCS-Revision: 1d6d2fa525e4b13476195b1d930dc523c88263df
X-VCS-Branch: master
Date: Wed, 13 Dec 2023 17:39:03 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: c8d2ff2b-fad4-4575-a544-8cf214ede00c
X-Archives-Hash: dff710ba0cbdd2c17dcbcb9b137b9d0d

commit:     1d6d2fa525e4b13476195b1d930dc523c88263df
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 13 17:38:37 2023 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Wed Dec 13 17:38:37 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1d6d2fa5

app-admin/salt: add 3006.5

Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 app-admin/salt/Manifest           |   1 +
 app-admin/salt/salt-3006.5.ebuild | 247 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 248 insertions(+)

diff --git a/app-admin/salt/Manifest b/app-admin/salt/Manifest
index 619f04c5ab60..d49bdb8a22a4 100644
--- a/app-admin/salt/Manifest
+++ b/app-admin/salt/Manifest
@@ -4,3 +4,4 @@ DIST salt-3005.4.tar.gz 17936876 BLAKE2B e06ec0e357fac18fe0ad823cf80e6261d80dbf2
 DIST salt-3006.2.tar.gz 20411634 BLAKE2B dff474017918ef3ee0031856a2739282077205d8c2589809a91e5f1c3741cb26d2bd2458734ea4d3533118c881851dfd853f4ba4f1c631e7db28e95bc1b6f7f8 SHA512 2626cb5beb1b30fc63f554f5804f0d9b7e36b7c569c5f9049e5f5ac5a413e9d99a98b3d91089683338e3d3890ec973dff80782b4e41acb291872e45084fd2546
 DIST salt-3006.3.tar.gz 20461738 BLAKE2B dfa4698dbc611c9c4954b4631d11b685e1efc978915918ce6d8f1890bb4a230d234b6a191166ffff9243058d44530bfc14b43386c8bc295c035c6609d6bf3fa0 SHA512 9cced766db2144de445ed53b52c1551c986ba43774c40512fd07973862d6d3a361e25f55fcfeeb0e03ba44eec1051909834e5d0a352ead5ec6f418b15c909628
 DIST salt-3006.4.tar.gz 20465324 BLAKE2B 8cf9acf8850e9eefbff32f3e347d8773ed7e28f58a0a441af9ec0a4c87a0bba49ff2b82e6f5816511de7303e16d79246df8c0024464a5c267f3ef7e370c8be98 SHA512 c48c69730ba81d3e279cbb01cb26c743dd8b4945c2fc16a7c959472ab4050316fcdaee935e009b7f472bd3b08172ac69defe64774a2d93e143a050cd559997ef
+DIST salt-3006.5.tar.gz 20536455 BLAKE2B cf475dc5e919f6ab180578db2aae5f3655623b39b134d67609da4f607be909340c6e55c940cfb66f129cc75d40b5cdda094e866db116d8a45aa5eef26d8fa1eb SHA512 8aaf5c5d36d8aa17b3fe867cee470f7b3c5dd1f6abaf5bdb49a3df76d3498d0dc1fa305a069bc95ad057489db229454b38b0ea9c1ade1e46b5d9b57aeef10c23

diff --git a/app-admin/salt/salt-3006.5.ebuild b/app-admin/salt/salt-3006.5.ebuild
new file mode 100644
index 000000000000..f6b28047c843
--- /dev/null
+++ b/app-admin/salt/salt-3006.5.ebuild
@@ -0,0 +1,247 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_10 )
+
+DISTUTILS_USE_PEP517=setuptools
+inherit systemd distutils-r1
+
+DESCRIPTION="Salt is a remote execution and configuration manager"
+HOMEPAGE="https://www.saltstack.com/resources/community/
+	https://github.com/saltstack"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}stack/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	inherit pypi
+	KEYWORDS="~amd64 ~riscv ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="
+	cheetah cherrypy ldap libcloud libvirt genshi gnupg keyring mako
+	mongodb neutron	nova openssl portage profile redis selinux test raet
+	+zeromq vim-syntax
+"
+
+RDEPEND="
+	sys-apps/pciutils
+	>=dev-python/cryptography-41.0.3[${PYTHON_USEDEP}]
+	>=dev-python/distro-1.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.1.2[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/libnacl[${PYTHON_USEDEP}]
+	dev-python/looseversion[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pycryptodome-3.9.8[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.1.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.31.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	libcloud? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/aiosignal[${PYTHON_USEDEP}]
+		>=dev-python/apache-libcloud-2.5.0[${PYTHON_USEDEP}]
+		dev-python/async-timeout[${PYTHON_USEDEP}]
+	)
+	mako? ( dev-python/mako[${PYTHON_USEDEP}] )
+	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+	libvirt? (
+		dev-python/libvirt-python[${PYTHON_USEDEP}]
+	)
+	openssl? (
+		dev-libs/openssl:0=[-bindist(-)]
+		>=dev-python/pyopenssl-23.2.0[${PYTHON_USEDEP}]
+	)
+	raet? (
+		>=dev-python/libnacl-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/ioflo-1.1.7[${PYTHON_USEDEP}]
+		>=dev-python/raet-0.6.0[${PYTHON_USEDEP}]
+	)
+	cherrypy? ( >=dev-python/cherrypy-3.2.2[${PYTHON_USEDEP}] )
+	cheetah? ( >=dev-python/cheetah3-3.2.2[${PYTHON_USEDEP}] )
+	genshi? ( dev-python/genshi[${PYTHON_USEDEP}] )
+	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
+	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
+	redis? ( dev-python/redis[${PYTHON_USEDEP}] )
+	selinux? ( sec-policy/selinux-salt )
+	nova? (
+		>=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}]
+	)
+	neutron? (
+		>=dev-python/python-neutronclient-2.3.6[${PYTHON_USEDEP}]
+	)
+	gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	profile? ( dev-python/yappi[${PYTHON_USEDEP}] )
+	vim-syntax? ( app-vim/salt-vim )
+	zeromq? ( >=dev-python/pyzmq-19.0.0[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	dev-python/build[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/apache-libcloud[${PYTHON_USEDEP}]
+		>=dev-python/boto-2.32.1[${PYTHON_USEDEP}]
+		>=dev-python/certifi-2023.07.22[${PYTHON_USEDEP}]
+		dev-python/cherrypy[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+		dev-python/mako[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/moto-2.0.0[${PYTHON_USEDEP}]
+		dev-python/passlib[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-7.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-salt-factories-1.0.0_rc28[${PYTHON_USEDEP}]
+		dev-python/pytest-tempdir[${PYTHON_USEDEP}]
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+		dev-python/pytest-shell-utilities[${PYTHON_USEDEP}]
+		dev-python/pytest-skip-markers[${PYTHON_USEDEP}]
+		dev-python/pytest-system-statistics[${PYTHON_USEDEP}]
+		dev-python/pytest-custom-exit-code[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		net-dns/bind-tools
+		>=dev-python/virtualenv-20.3.0[${PYTHON_USEDEP}]
+		dev-util/yamllint[${PYTHON_USEDEP}]
+		!x86? ( >=dev-python/boto3-1.21.46[${PYTHON_USEDEP}] )
+	)
+"
+
+DOCS=( README.rst AUTHORS )
+
+REQUIRED_USE="|| ( raet zeromq )
+	test? ( cheetah genshi )"
+RESTRICT="!test? ( test ) x86? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/salt-3003-gentoolkit-revdep.patch"
+	"${FILESDIR}/salt-3005.1-no-entry-points.patch"
+	"${FILESDIR}/salt-3006-skip-tests-that-oom-machine.patch"
+)
+
+python_prepare_all() {
+	# remove tests with external dependencies that may not be available, and
+	# tests that don't work in sandbox
+	rm tests/unit/{test_{zypp_plugins,module_names},utils/test_extend}.py || die
+	rm tests/unit/modules/test_boto_{vpc,secgroup,elb}.py || die
+	rm tests/unit/states/test_boto_vpc.py || die
+
+	#rm tests/support/gitfs.py || die
+	rm tests/pytests/functional/transport/server/test_req_channel.py || die
+	rm tests/pytests/functional/utils/test_async_event_publisher.py || die
+	rm tests/pytests/functional/runners/test_winrepo.py || die
+	rm tests/unit/netapi/rest_tornado/test_saltnado.py || die
+
+	# tests that require network access
+	rm tests/unit/{states,modules}/test_zcbuildout.py || die
+	rm -r tests/integration/cloud || die
+	rm -r tests/kitchen/tests/wordpress/tests || die
+	rm tests/kitchen/test_kitchen.py || die
+	rm tests/unit/modules/test_network.py || die
+	rm tests/pytests/functional/modules/test_pip.py || die
+	rm tests/pytests/unit/client/ssh/test_ssh.py || die
+	rm -r tests/pytests/{integration,functional}/netapi tests/integration/netapi || die
+
+	# tests require root access
+	rm tests/integration/pillar/test_git_pillar.py || die
+	rm tests/integration/states/test_supervisord.py || die
+	rm tests/pytests/scenarios/performance/test_performance.py || die
+
+	# removes contextvars, see bug: https://bugs.gentoo.org/799431
+	sed -i '/^contextvars/d' requirements/base.txt || die
+
+	# make sure pkg_resources doesn't bomb because pycrypto isn't installed
+	find "${S}" -name '*.txt' -print0 | xargs -0 sed -e '/pycrypto>/ d ; /pycryptodomex/ d' -i || die
+	# pycryptodome rather than pycryptodomex
+	find "${S}" -name '*.py' -print0 | xargs -0 -- sed -i -e 's:Cryptodome:Crypto:g' -- || die
+	# called_once should be assert_called_once_with
+	find "${S}/tests" -name '*.py' -print0 | xargs -0 -- sed -i -e 's:[.]called_once:.assert_called_once:g' -- || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	local svc
+	USE_SETUPTOOLS=1 distutils-r1_python_install_all
+
+	for svc in minion master syndic api; do
+		newinitd "${FILESDIR}"/${svc}-initd-5 salt-${svc}
+		newconfd "${FILESDIR}"/${svc}-confd-1 salt-${svc}
+		systemd_dounit "${FILESDIR}"/salt-${svc}.service
+	done
+
+	insinto /etc/${PN}
+	doins -r conf/*
+}
+
+python_test() {
+	local -a EPYTEST_DESELECT=(
+		# doesn't like the distutils warning
+		tests/pytests/integration/cli/test_batch.py::test_batch_retcode
+		tests/pytests/integration/cli/test_batch.py::test_multiple_modules_in_batch
+		# hangs indefinitely
+		tests/pytests/unit/test_minion.py::test_master_type_disable
+		# needs root
+		tests/pytests/unit/modules/test_cmdmod.py::test_runas_env_sudo_group
+		# don't like sandbox
+		tests/pytests/functional/cli/test_salt.py::test_help_log
+		tests/pytests/functional/cli/test_salt.py::test_versions_report
+		tests/pytests/integration/ssh/test_pillar_compilation.py::test_gpg_pillar
+		tests/pytests/integration/ssh/test_pillar_compilation.py::test_saltutil_runner
+		tests/unit/utils/test_vt.py::test_split_multibyte_characters_unicode
+		tests/unit/utils/test_vt.py::test_split_multibyte_characters_shiftjis
+		tests/pytests/unit/utils/test_vt.py::test_log_sanitize
+		tests/pytests/unit/client/ssh/test_single.py::test_run_with_pre_flight_args
+		tests/pytests/unit/modules/test_aptpkg.py::test_call_apt_dpkg_lock
+		tests/pytests/unit/modules/test_yumpkg.py::test_get_yum_config
+		tests/pytests/unit/test_master.py::test_fileserver_duration
+		tests/pytests/unit/test_template.py::test_compile_template_str_mkstemp_cleanup
+		tests/pytests/unit/_logging/handlers/test_deferred_stream_handler.py::test_deferred_write_on_flush
+		tests/pytests/unit/_logging/handlers/test_deferred_stream_handler.py::test_sync_with_handlers
+		tests/pytests/unit/modules/test_portage_config.py::test_enforce_nice_config
+		tests/pytests/unit/modules/test_msteams.py::test_post_card
+		tests/pytests/unit/renderers/test_yamlex.py::test_basic
+		tests/pytests/unit/renderers/test_yamlex.py::test_complex
+		tests/pytests/unit/states/test_file.py::test_file_recurse_directory_test
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_anyof_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_dict_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_hostname_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_not_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_oneof_config_validation
+		tests/unit/utils/test_schema.py::ConfigTestCase::test_optional_requirements_config_validation
+		# tests that need network access
+		tests/pytests/unit/utils/test_http.py::test_query_proxy
+		tests/pytests/unit/utils/test_http.py::test_backends_decode_body_false
+		tests/pytests/unit/utils/test_http.py::test_backends_decode_body_true
+		tests/pytests/unit/utils/test_network.py::test_isportopen
+	)
+
+	# testsuite likes lots of files
+	ulimit -n 4096 || die
+
+	# ${T} is too long a path for the tests to work
+	local TMPDIR
+	TMPDIR="$(mktemp --directory --tmpdir=/tmp ${PN}-XXXX)" || die
+	(
+		export TMPDIR
+		cleanup() { rm -rf "${TMPDIR}" || die; }
+
+		trap cleanup EXIT
+
+		addwrite "${TMPDIR}"
+
+		USE_SETUPTOOLS=1 NO_INTERNET=1 SHELL="/bin/bash" \
+			epytest
+	)
+}