[gentoo-commits] repo/gentoo:master commit in: net-misc/tuba/

["Michał Górny" <mgorny@gentoo.org>]

commit:     946ee53012bb18fe374f673c96c1bcf946f4661b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 12 06:49:30 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec 12 06:49:52 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=946ee530

net-misc/tuba: Add a live ebuild

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/tuba/tuba-9999.ebuild | 66 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/net-misc/tuba/tuba-9999.ebuild b/net-misc/tuba/tuba-9999.ebuild
new file mode 100644
index 000000000000..94c20661a979
--- /dev/null
+++ b/net-misc/tuba/tuba-9999.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit git-r3 gnome2-utils meson optfeature vala
+
+DESCRIPTION="Browse the Fediverse (GTK client)"
+HOMEPAGE="
+	https://tuba.geopjr.dev/
+	https://github.com/GeopJr/Tuba/
+"
+EGIT_REPO_URI="https://github.com/GeopJr/Tuba.git"
+
+LICENSE="GPL-3 CC-BY-SA-4.0"
+SLOT="0"
+
+# TODO: optional dep on libspelling-1
+DEPEND="
+	app-crypt/libsecret[introspection]
+	>=dev-libs/glib-2.76.0:2
+	>=dev-libs/json-glib-1.4.4[introspection]
+	>=dev-libs/libgee-0.8.5:0.8[introspection]
+	dev-libs/libxml2
+	>=gui-libs/gtk-4.11.3:4[gstreamer,introspection]
+	>=gui-libs/libadwaita-1.4:1[introspection,vala]
+	>=gui-libs/gtksourceview-5.6.0:5[introspection,vala]
+	net-libs/libsoup:3.0[introspection]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	$(vala_depend)
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		# disable calling updaters (see pkg_post*)
+		-Ddistro=true
+	)
+
+	vala_setup
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dosym dev.geopjr.Tuba /usr/bin/tuba
+}
+
+pkg_postinst() {
+	optfeature "WebP image support" gui-libs/gdk-pixbuf-loader-webp
+
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}