[gentoo-commits] proj/kde:master commit in: kde-frameworks/kinit/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     78013b94841a4f9ad4db6328ba5593bf34612a0a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  6 17:07:35 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Dec  6 17:16:03 2023 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=78013b94

kde-frameworks/kinit: 5.113.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/kinit/kinit-5.113.0.ebuild | 48 +++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/kde-frameworks/kinit/kinit-5.113.0.ebuild b/kde-frameworks/kinit/kinit-5.113.0.ebuild
new file mode 100644
index 0000000000..678fe74805
--- /dev/null
+++ b/kde-frameworks/kinit/kinit-5.113.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+ECM_TEST="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org
+
+DESCRIPTION="Helper library to speed up start of applications on KDE workspaces"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+caps +man X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kcrash-${PVCUT}*:5
+	=kde-frameworks/kdbusaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	=kde-frameworks/kio-${PVCUT}*:5
+	=kde-frameworks/kservice-${PVCUT}*:5
+	=kde-frameworks/kwindowsystem-${PVCUT}*:5[X?]
+	caps? ( sys-libs/libcap )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package caps Libcap)
+		$(cmake_use_find_package man KF5DocTools)
+		-DWITH_X11=$(usex X)
+	)
+
+	ecm_src_configure
+}