[gentoo-commits] repo/gentoo:master commit in: dev-python/fsspec/

["Michał Górny" <mgorny@gentoo.org>]

commit:     15105e82539235b2319065630050d407278de233
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  3 03:09:13 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Dec  3 04:20:15 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=15105e82

dev-python/fsspec: Bump to 2023.12.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/fsspec/Manifest                |  1 +
 dev-python/fsspec/fsspec-2023.12.0.ebuild | 65 +++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-python/fsspec/Manifest b/dev-python/fsspec/Manifest
index 1f457fdadb22..8e43e2a16328 100644
--- a/dev-python/fsspec/Manifest
+++ b/dev-python/fsspec/Manifest
@@ -1 +1,2 @@
 DIST filesystem_spec-2023.10.0.gh.tar.gz 404845 BLAKE2B 6c8cf801664c9fc848cb55660db1725c90facf534d58e49f604b2051d1b6a78d13d8f083282071beb7ab3dcb8d75f6d52fe24ce744c5cf1808b4ae3cb673998d SHA512 cb449052208516930c73dbe1de7c495d252677a3d3d85267836224d79c1b8cf9449ebdba8287f6f6206d5a8e631a99cd81c2fb62b82288a626a202876a45139c
+DIST filesystem_spec-2023.12.0.gh.tar.gz 408457 BLAKE2B d46383ff22124b714b58264e203a12fad13ee17fb8124d949c107546cceaf2713d52e1e33e0a9d63017695681ab9e8dfb86f85da809675fba7b1838f3a12a486 SHA512 87bdd147cfddaf971af6c0c34dafb47b6d1782c7a0eb2ec7fbcbf01f6d01b59ecea98b9bf75461827e9e1070f78346b53e753673838e1db505d33f9fa8d59349

diff --git a/dev-python/fsspec/fsspec-2023.12.0.ebuild b/dev-python/fsspec/fsspec-2023.12.0.ebuild
new file mode 100644
index 000000000000..1cdf466d85da
--- /dev/null
+++ b/dev-python/fsspec/fsspec-2023.12.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+MY_P=filesystem_spec-${PV}
+DESCRIPTION="A specification that python filesystems should adhere to"
+HOMEPAGE="
+	https://github.com/fsspec/filesystem_spec/
+	https://pypi.org/project/fsspec/
+"
+SRC_URI="
+	https://github.com/fsspec/filesystem_spec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+# Note: this package is not xdist-friendly
+distutils_enable_tests pytest
+
+src_test() {
+	git config --global user.email "you@example.com" || die
+	git config --global user.name "Your Name" || die
+	distutils-r1_src_test
+}
+
+EPYTEST_DESELECT=(
+	fsspec/tests/test_spec.py::test_find
+	# requires s3fs
+	fsspec/implementations/tests/test_local.py::test_urlpath_inference_errors
+	fsspec/tests/test_core.py::test_mismatch
+	# requires pyarrow, fastparquet
+	fsspec/implementations/tests/test_reference.py::test_df_single
+	fsspec/implementations/tests/test_reference.py::test_df_multi
+)
+
+EPYTEST_IGNORE=(
+	# sftp and smb require server started via docker
+	fsspec/implementations/tests/test_dbfs.py
+	fsspec/implementations/tests/test_sftp.py
+	fsspec/implementations/tests/test_smb.py
+	# unhappy about dev-python/fuse-python (?)
+	fsspec/tests/test_fuse.py
+)