[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     d82023d8b4c4539fe179310ddd5b649e10eb4473
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 29 16:42:28 2023 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Wed Nov 29 18:26:21 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d82023d8

www-client/opera-developer: automated bump (106.0.4993.0)

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-106.0.4993.0.ebuild            | 170 +++++++++++++++++++++
 2 files changed, 171 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 483bf755535a..03083779d609 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,5 +1,6 @@
 DIST opera-developer_106.0.4971.0_amd64.deb 111013652 BLAKE2B 2deaf68cced226106c03e38c0d0f773d75795be2b98b505dfb691fd9d8e707484f9e48d3b31f7723b0d68a4bef44463e073b18fd3822e0265258d088af0c1655 SHA512 02ffef24ab5d2dceb625eff70f5bad97cd4f82e7d00a796bda454c4670310837c950a67ef5d16da6b5e4eb2475168d12a5be970259c3c046c67384ca01fe0d72
 DIST opera-developer_106.0.4977.0_amd64.deb 111042244 BLAKE2B c5f44e10bda1e575fa6d0422521c5136a57887dd866a7e3917267da8c7240880af49094723b34a5c4e900a3575413c340d04dd3564ec5a11a272fbfc028ac32b SHA512 a2ebe6a796b814a72ecc3673b1075262c07b1e61e512bd9bea3dffc2b5a0ef204909fb1592c6ca460045dfaf5e0f3808ba89e42ab20af4b081d13ca20e67dd1a
 DIST opera-developer_106.0.4985.0_amd64.deb 110024152 BLAKE2B 341bbed6b6d92d590027902c9b71e1984dd84239db05a048fd1bedf91f8ced50463493ad71f02bb2bc659e4badde41a98c46933c1edf4bf0fef6cf8416cacae0 SHA512 4aea1632257171c011231bc40589020c5824d6b722688aa312256cfc04ee661bf3a37f09d4925e11261ba78e874193070603de8f3531857eb2657ba2a269caf0
+DIST opera-developer_106.0.4993.0_amd64.deb 107348028 BLAKE2B 1de99ea3a18e6f4891634e14e2168d6d1eb3af8eba2bde7545a5862c534696d79fdce7f8a7bd211a1badd150e2e73b409b1df8af02aa65766f8ab49c37ec5fc5 SHA512 f512a97557d4c895b67c480bf0e02713e648865af3aa48c25548f5f67690b5b329271e81e553f324ab88f0880c1151e66d906f31a8c57868a7966d49af9aef91
 DIST opera-developer_106.0.4998.0_amd64.deb 108032064 BLAKE2B 3362ee320789eb7ce35b2498704f91b5db42f32a8548280c23fb32c7a7160497e5158cbf1c39c84da8ff3503bb70b4de672d2b584bcf28b070b98074b70fb299 SHA512 a626fc520d4ea417d2fa797b9a18bca1b89a830b0f1254ae982eb0c01eade78e9cd4598f9c69bf40f9f4b1cfa96faee7af6461b95f51e78def4c432e82f39c44
 DIST opera-ffmpeg-codecs-114.0.5735.9.tar.xz 1315192 BLAKE2B ef9a0cfc8c30ac0a837863644f3c2d5e78059575e2b8f6fda9253304f4815a39d021602e802dac7e1d5a1685aa5015a02019c4a0399f0bdc81136f956cc1d55f SHA512 bdad66bd5d238bdeb81a4e2a956f0a814633360f05c7bed2161df9506d2ccc444445ba452cc8974c755fe0d3f46adceb90324a472a5dac72e9c65391ae7a841c

diff --git a/www-client/opera-developer/opera-developer-106.0.4993.0.ebuild b/www-client/opera-developer/opera-developer-106.0.4993.0.ebuild
new file mode 100644
index 000000000000..fa627a202454
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-106.0.4993.0.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="114.0.5735.9"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs +suid qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}