[gentoo-commits] repo/gentoo:master commit in: net-analyzer/bmon/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     fb63d9f1c3e0c1eee0deb6856a2d6ca1977e5bcd
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Wed Nov  1 18:27:55 2023 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Wed Nov 22 10:55:33 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fb63d9f1

net-analyzer/bmon: EAPI8, install missing DOCS

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 net-analyzer/bmon/bmon-4.0-r1.ebuild | 43 ++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/net-analyzer/bmon/bmon-4.0-r1.ebuild b/net-analyzer/bmon/bmon-4.0-r1.ebuild
new file mode 100644
index 000000000000..15ff96ce5102
--- /dev/null
+++ b/net-analyzer/bmon/bmon-4.0-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info toolchain-funcs
+
+DESCRIPTION="Interface bandwidth monitor"
+HOMEPAGE="https://github.com/tgraf/bmon/"
+SRC_URI="https://codeload.github.com/tgraf/${PN}/tar.gz/v${PV} -> ${P}.tar.gz"
+
+LICENSE="BSD-2 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.3-r2:0=
+	dev-libs/confuse:=
+	dev-libs/libnl:3
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( ChangeLog NEWS README )
+
+CONFIG_CHECK="~NET_SCHED"
+ERROR_NET_SCHED="
+	CONFIG_NET_SCHED is not set when it should be.
+	Run ${PN} -i proc to use the deprecated proc interface instead.
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.6-docdir-examples.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf CURSES_LIB="$("$(tc-getPKG_CONFIG)" --libs ncurses)"
+}