[gentoo-commits] repo/gentoo:master commit in: profiles/features/musl/, sys-power/sandmann-bin/

[gentoo-commits] repo/gentoo:master commit in: profiles/features/musl/, sys-power/sandmann-bin/

[Florian Schmaus]

commit:     cf45ee482e7e42ff360f0b65f74c7ccbd156ebe9
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 22 08:29:34 2023 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Wed Nov 22 08:31:04 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cf45ee48

sys-power/sandmann-bin: new package, add 0.9

Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 profiles/features/musl/package.mask            |  4 ++
 sys-power/sandmann-bin/Manifest                |  1 +
 sys-power/sandmann-bin/metadata.xml            |  8 ++++
 sys-power/sandmann-bin/sandmann-bin-0.9.ebuild | 61 ++++++++++++++++++++++++++
 4 files changed, 74 insertions(+)

diff --git a/profiles/features/musl/package.mask b/profiles/features/musl/package.mask
index 7f515a86104b..8466238a2352 100644
--- a/profiles/features/musl/package.mask
+++ b/profiles/features/musl/package.mask
@@ -1,6 +1,10 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# Florian Schmaus <flow@gentoo.org> (2023-11-22)
+# Requires systemd which is not supported on musl.
+sys-power/sandmann-bin
+
 # Maciej Barć <xgqt@gentoo.org> (2023-09-16)
 # Binary package, which is compiled against glibc
 dev-lang/dafny-bin

diff --git a/sys-power/sandmann-bin/Manifest b/sys-power/sandmann-bin/Manifest
new file mode 100644
index 000000000000..9c45a637fdcf
--- /dev/null
+++ b/sys-power/sandmann-bin/Manifest
@@ -0,0 +1 @@
+DIST sandmann-0.9.tar.xz 16656160 BLAKE2B e0b52fd8ba67bec68dfa6a6c6fa3f9321118c350a954cef582643339f1d15c6f8d55d74cfbc0d1894dd5eae83975f1ef57c974c5035b80d9bdc1e132d7b16787 SHA512 bee9a9b5f5eaaeba8ec66999c2719efb43cd85c601a9aee61017dd330149ed9faf94a48d9c0fd0dcc82c05fa8dfe23f020d69b452bb71ccf5dc50017dcf5a84e

diff --git a/sys-power/sandmann-bin/metadata.xml b/sys-power/sandmann-bin/metadata.xml
new file mode 100644
index 000000000000..87a759d410cf
--- /dev/null
+++ b/sys-power/sandmann-bin/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Florian Schmaus</name>
+		<email>flow@gentoo.org</email>
+	</maintainer>
+</pkgmetadata>

diff --git a/sys-power/sandmann-bin/sandmann-bin-0.9.ebuild b/sys-power/sandmann-bin/sandmann-bin-0.9.ebuild
new file mode 100644
index 000000000000..a56afa598bc2
--- /dev/null
+++ b/sys-power/sandmann-bin/sandmann-bin-0.9.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-utils-2 systemd tmpfiles
+
+MY_PN=${PN%-bin}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="An autosuspend and wakeup daemon"
+HOMEPAGE="https://gitlab.gentoo.org/flow/sandmann"
+SRC_URI="https://dev.gentoo.org/~flow/${MY_PN}/archive/${MY_P}.tar.xz"
+KEYWORDS="~amd64"
+
+LICENSE="GPL-3+ LGPL-3"
+SLOT="0"
+
+# >=java-config-2.3.2 to get the libdir fix.
+RDEPEND="
+	>=dev-java/java-config-2.3.2
+	sys-apps/systemd
+	sys-auth/polkit
+	|| (
+		virtual/jre:17
+		virtual/jre:21
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	sed -i \
+		-e 's|^ExecStart=.*|ExecStart=/usr/bin/sandmann|' \
+		sandmann.service || die
+}
+
+src_compile() {
+	:
+}
+
+src_install() {
+	local my_emake_args=(
+		DESTDIR="${D}"
+		SYSTEMD_SYSTEM_UNIT_DIR="$(systemd_get_systemunitdir)"
+		TARGET_BINARY=
+		SOURCELESS_INSTALL=true
+	)
+
+	emake ${my_emake_args[@]} install
+
+	java-pkg_newjar out/main/assembly.dest/out.jar sandmann.jar
+	java-pkg_dolauncher sandmann
+
+	dodoc README.md
+}
+
+pkg_postinst() {
+	tmpfiles_process sandmann.conf
+}