[gentoo-commits] repo/gentoo:master commit in: dev-python/nbdime/

["Michał Górny" <mgorny@gentoo.org>]

commit:     8c166168b34d45572ccace10ae8034d5fa210b19
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 21 17:27:36 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov 21 19:05:00 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8c166168

dev-python/nbdime: Bump to 4.0.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nbdime/Manifest            |  1 +
 dev-python/nbdime/nbdime-4.0.1.ebuild | 58 +++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/nbdime/Manifest b/dev-python/nbdime/Manifest
index 778acd0325ed..f08ddbc2ab60 100644
--- a/dev-python/nbdime/Manifest
+++ b/dev-python/nbdime/Manifest
@@ -1 +1,2 @@
 DIST nbdime-3.2.1.tar.gz 7642926 BLAKE2B 245a2b0ca112574a9622855acc8db43595cd7f29f6fe2c1a1f70254984edb395817f65246613b5f41f513464fd37264f2c520237bf44570814bfa6131fdf22a8 SHA512 6ead97a88d587dab00df22d59adb2b80b7f81f47929a6be94b5e848a5c72f7420fac49e1a6a3b87138db75e6c1f46eef67a57a58d6e9d568b69f4e555bb7ed60
+DIST nbdime-4.0.1.tar.gz 9414125 BLAKE2B bf2581cec0f71ef8949c9cf19e21aa47302b6c71bbb9861e8c6f3a4b1921e9f73460ee5059e5bc92c7789d8f0695329125725c10e10763dd6e4d388bfaee53d1 SHA512 df14dfe9df296d71eb4a98140fe15703ca277063a153c3159cc883c99ce98b76f5f4dae24d32b048a18d2530e52535e3d89523d7a1c54a8654d2d54c8812ded3

diff --git a/dev-python/nbdime/nbdime-4.0.1.ebuild b/dev-python/nbdime/nbdime-4.0.1.ebuild
new file mode 100644
index 000000000000..9e50c7b8d3c0
--- /dev/null
+++ b/dev-python/nbdime/nbdime-4.0.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Diff and merge of Jupyter Notebooks"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/nbdime/
+	https://pypi.org/project/nbdime/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/GitPython[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter-server[${PYTHON_USEDEP}]
+	dev-python/jupyter-server-mathjax[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	dev-python/recommonmark \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_test() {
+	# user.email and user.name are not configured in the sandbox
+	git config --global user.email "larry@gentoo.org" || die
+	git config --global user.name "Larry the Cow" || die
+
+	distutils-r1_src_test
+}
+
+src_install() {
+	distutils-r1_src_install
+	mv "${ED}"{/usr,}/etc || die
+}