[gentoo-commits] repo/gentoo:master commit in: x11-misc/polybar/

["John Helmert III" <ajak@gentoo.org>]

commit:     5314d493a827d231427068cce2d1372c0f6079d9
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 20 14:35:21 2023 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Mon Nov 20 14:36:18 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5314d493

x11-misc/polybar: add 3.7.0

Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 x11-misc/polybar/Manifest             |  1 +
 x11-misc/polybar/polybar-3.7.0.ebuild | 62 +++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/x11-misc/polybar/Manifest b/x11-misc/polybar/Manifest
index dbdf109b7eae..9f2b24f1d014 100644
--- a/x11-misc/polybar/Manifest
+++ b/x11-misc/polybar/Manifest
@@ -1 +1,2 @@
 DIST polybar-3.6.3.tar.gz 439838 BLAKE2B 522e95bb11e947008f0909401a769ba7ef44733e7edb4a067185bad610ac70077e1370e0e9da9fbff27b9f981b5285561f7c86e12fc5da79c383d794da6b4a86 SHA512 d8e08d2b217a353b967f58eb61907b05ed7b9c2b9e1b3a891f4cac91b37f1cf751b10b1e93e74e6414eb0beb1696f4ae64a0a43bfc6c0afa3863b72293217c2e
+DIST polybar-3.7.0.tar.gz 494588 BLAKE2B 3b07cbee50c12fcdddedd79b0601e218b0016abd0d5b0ae7cfa0bda3c8c09a30ab3b606fdfac0207dbb51caccbe08f37275f4cfd81af21d5b706cc7706ea0d8e SHA512 ddc62fad546052a47b8235d44fb679349e95e19809d8a59f7178617ca33ff18e2507c7dcc7e15a5b2815088e91db40a66f0846aaf181b85dc5cebbaa4f758322

diff --git a/x11-misc/polybar/polybar-3.7.0.ebuild b/x11-misc/polybar/polybar-3.7.0.ebuild
new file mode 100644
index 000000000000..452904b5f71e
--- /dev/null
+++ b/x11-misc/polybar/polybar-3.7.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="A fast and easy-to-use tool for creating status bars"
+HOMEPAGE="https://github.com/polybar/polybar"
+SRC_URI="https://github.com/polybar/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~riscv ~x86"
+LICENSE="MIT"
+SLOT="0"
+IUSE="alsa curl doc i3wm ipc mpd network pulseaudio"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep 'x11-base/xcb-proto[${PYTHON_USEDEP}]')
+	dev-libs/libuv:=
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/cairo[X,xcb(+)]
+	x11-libs/libxcb:=
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-wm
+	x11-libs/xcb-util-xrm
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	doc? ( dev-python/sphinx )
+	i3wm? (
+		dev-libs/jsoncpp:=
+		x11-wm/i3
+	)
+	mpd? ( media-libs/libmpdclient )
+	network? ( dev-libs/libnl:3 )
+	pulseaudio? ( media-libs/libpulse )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ALSA="$(usex alsa)"
+		-DENABLE_CURL="$(usex curl)"
+		-DBUILD_DOC="$(usex doc)"
+		-DENABLE_I3="$(usex i3wm)"
+		-DBUILD_POLYBAR_MSG="$(usex ipc)"
+		-DENABLE_MPD="$(usex mpd)"
+		-DENABLE_NETWORK="$(usex network)"
+		-DENABLE_PULSEAUDIO="$(usex pulseaudio)"
+		# Bug 767949
+		-DENABLE_CCACHE="OFF"
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc/"
+	)
+
+	cmake_src_configure
+}