[gentoo-commits] repo/gentoo:master commit in: dev-python/pytest-testinfra/

["Michał Górny" <mgorny@gentoo.org>]

commit:     0d202fac9f0481100536ee616cb6f161e9009a98
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 14 04:23:17 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov 14 04:34:02 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0d202fac

dev-python/pytest-testinfra: Bump to 10.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pytest-testinfra/Manifest               |  1 +
 .../pytest-testinfra-10.0.0.ebuild                 | 57 ++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-python/pytest-testinfra/Manifest b/dev-python/pytest-testinfra/Manifest
index 15f6385581e6..010879cf0106 100644
--- a/dev-python/pytest-testinfra/Manifest
+++ b/dev-python/pytest-testinfra/Manifest
@@ -1 +1,2 @@
+DIST pytest-testinfra-10.0.0.tar.gz 84667 BLAKE2B 10c62340af7cb0a07cbc3c8099f0d22bbf8e3623e8c5f80dd45acef23ec178a2b090aa012e5602c7b67d0ef61ca9922d05e412e8db62384589080455326c8abc SHA512 3f289fccc3ba38ed1aa316adbb05ef74f51fbd1130ab7a39c5d56a11124de96c048aecef3a19438cd0d50d4891ed843671d9daf50fc5c3fb5c834164b276529d
 DIST pytest-testinfra-9.0.0.tar.gz 83896 BLAKE2B 8d75bf051ec91916dcb9bc727409eefbf53f8635b5dd953d2c1d05a1d4daa37ade01a23bcc004f77ced37d8fb30684df211d16d95839c1a8d8e5d5c4df5336ca SHA512 bbf66597c473b868f0dde0437d666f8235e835a35bfd12b4a86f9970e26c1963d83101e7e0e3b3817e23798bee342f47ac7666041f0e09038236f9ddca4afecf

diff --git a/dev-python/pytest-testinfra/pytest-testinfra-10.0.0.ebuild b/dev-python/pytest-testinfra/pytest-testinfra-10.0.0.ebuild
new file mode 100644
index 000000000000..6af6abc9e956
--- /dev/null
+++ b/dev-python/pytest-testinfra/pytest-testinfra-10.0.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Write unit tests in Python to test actual state of your servers"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-testinfra/
+	https://pypi.org/project/pytest-testinfra/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	dev-python/pytest[${PYTHON_USEDEP}]
+"
+# Ansible is called via its CLI
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		app-admin/ansible
+		$(python_gen_cond_dep '
+			app-admin/salt[${PYTHON_USEDEP}]
+		' python3_10)
+		dev-python/paramiko[${PYTHON_USEDEP}]
+		dev-python/pywinrm[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x EPYTEST_DESELECT=()
+
+	# This is the only test which actually fails if salt cannot be imported
+	if ! has_version "dev-python/salt[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			test/test_backends.py::test_backend_importables
+		)
+	fi
+
+	epytest
+}
+
+pkg_postinst() {
+	elog "For the list of available connection back-ends and their dependencies,"
+	elog "please consult https://testinfra.readthedocs.io/en/latest/backends.html"
+}