[gentoo-commits] repo/gentoo:master commit in: app-text/gocr/

["Sam James" <sam@gentoo.org>]

commit:     4e23e485041abd1d2a16a3d3bd8afd5e3b911324
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 13 07:32:50 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Nov 13 07:32:50 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4e23e485

app-text/gocr: migrate to fig2dev

Closes: https://bugs.gentoo.org/917255
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-text/gocr/gocr-0.52-r1.ebuild | 53 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/app-text/gocr/gocr-0.52-r1.ebuild b/app-text/gocr/gocr-0.52-r1.ebuild
new file mode 100644
index 000000000000..c598b8bc26bd
--- /dev/null
+++ b/app-text/gocr/gocr-0.52-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="An OCR (Optical Character Recognition) reader"
+HOMEPAGE="https://www-e.uni-magdeburg.de/jschulen/ocr/"
+SRC_URI="http://www-e.uni-magdeburg.de/jschulen/ocr/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc scanner tk"
+
+DEPEND="
+	>=media-libs/netpbm-9.12
+	doc? (
+		>=media-gfx/fig2dev-3.2.9-r1
+		app-text/ghostscript-gpl
+	)
+	tk? ( dev-lang/tk )"
+RDEPEND="${DEPEND}
+	tk? (
+		media-gfx/xli
+		scanner? ( media-gfx/xsane )
+	)"
+
+src_compile() {
+	local targets=( src man )
+	use doc && targets+=( doc examples )
+
+	emake "${targets[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" exec_prefix="${EPREFIX}/usr" install
+	einstalldocs
+	dodoc HISTORY REMARK.txt REVIEW
+
+	# remove the tk frontend if tk is not selected
+	if ! use tk; then
+		rm "${ED}"/usr/bin/gocr.tcl || die
+	fi
+
+	# and install the documentation and examples
+	if use doc; then
+		dodoc doc/gocr.html doc/examples.txt doc/unicode.txt
+
+		docinto examples
+		dodoc examples/*.{fig,tex,pcx}
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}