[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-session/

["Jimi Huotari" <chiitoo@gentoo.org>]

commit:     6a7e8099f35abb302c5f462c87710497658efc03
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  9 19:24:35 2023 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Thu Nov  9 21:45:32 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a7e8099

lxqt-base/lxqt-session: add 1.4.0

Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 lxqt-base/lxqt-session/Manifest                  |  1 +
 lxqt-base/lxqt-session/lxqt-session-1.4.0.ebuild | 62 ++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/lxqt-base/lxqt-session/Manifest b/lxqt-base/lxqt-session/Manifest
index 948338165e76..2a99d1866033 100644
--- a/lxqt-base/lxqt-session/Manifest
+++ b/lxqt-base/lxqt-session/Manifest
@@ -1 +1,2 @@
 DIST lxqt-session-1.3.0.tar.xz 186860 BLAKE2B 7b52f82f2d4bc75bf03e7d2e3456797238ea91856088b2e39f8b5caa4f4f55ab92292e875d3aeb845e96e98435936a1fb0bf6db1c1d04091f5df80d75745bb22 SHA512 4ad358ad8a01fe6df697cb4dc19abee7ed9b37dce13022e2fc1b309a5adbb942c69fc4de401fbc16e51394d38482a98bf2f5ebcc0a64194e03bd714691ad96db
+DIST lxqt-session-1.4.0.tar.xz 188324 BLAKE2B 508509a783f747c3dd72984264056466d8f9ef901b4a7731fbecca575951c528231cdb71a799ab7d617ed86c29d9026d9feb8fbb2b795a39958c1948d75812c2 SHA512 4f5731969582222eef9d0d2f2b37c4a160c3c6469f3a16cb4b1804ba76a9320d36b0ed91cada6ee905339ed8cfbd443851804086d978424c4d79045cc90e1629

diff --git a/lxqt-base/lxqt-session/lxqt-session-1.4.0.ebuild b/lxqt-base/lxqt-session/lxqt-session-1.4.0.ebuild
new file mode 100644
index 000000000000..f70701aa5019
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-1.4.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt Session Manager"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="+udev"
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+	>=dev-util/lxqt-build-tools-0.13.0
+"
+DEPEND="
+	>=app-misc/qtxdg-tools-3.11.0
+	>=dev-libs/libqtxdg-3.12.0
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-process/procps:=
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	udev? ( virtual/libudev:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	newenvd - 91lxqt-config-dir <<- _EOF_
+		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
+	_EOF_
+}