[gentoo-commits] repo/gentoo:master commit in: app-crypt/gpgme/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     aea794a80d7a01975b13e2950b0a7e631648c82b
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  5 23:53:01 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Nov  6 18:13:01 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aea794a8

app-crypt/gpgme: drop 1.21.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-crypt/gpgme/Manifest            |   2 -
 app-crypt/gpgme/gpgme-1.21.0.ebuild | 163 ------------------------------------
 2 files changed, 165 deletions(-)

diff --git a/app-crypt/gpgme/Manifest b/app-crypt/gpgme/Manifest
index d94b7cafdf4f..3aa054a55951 100644
--- a/app-crypt/gpgme/Manifest
+++ b/app-crypt/gpgme/Manifest
@@ -1,5 +1,3 @@
-DIST gpgme-1.21.0.tar.bz2 1830113 BLAKE2B 77000567fde5b78bf46352b25c81e7223506c00703360c87d3bd05afde29ef33d7f9f82e2dbe20f4e64bb6d99a0d8f442d88762d14a72b7ddabf5b38be62e130 SHA512 eb70813d22920d6d54459a4271259edf55d5833edfdd053551ca245521e06a8c19ed02dc93e0c53132a699e6d8c82499f50caf8e390af28468e3549470595b7d
-DIST gpgme-1.21.0.tar.bz2.sig 119 BLAKE2B ac19a5694e139be36ee9c6e28501d4a695166cfbc8f1561de7c7741a274f35cb0a67f779b5fc1ff58b5a11eeaa5e575c06233be65d01c40504efe16a759740ea SHA512 8a471333fd0fc6da50990c3aed67900a6b183cde0fcc449d37435289d8f309c68555c741281c06af9740ac088ae0b4747263da1dfd23d90b050185706948b227
 DIST gpgme-1.22.0.tar.bz2 1717836 BLAKE2B 6c03f4252391a114233fed284bf9eba03fa7b67328b506c01554fbd4239e0f3ede0bc79d82e9f21718084ca17945d628707d4451ac765a8f36d282e7e2d75f8e SHA512 17053053fa885f01416433e43072ac716b5d5db0c3edf45b2d6e90e6384d127626e6ae3ce421abba8f449f5ca7e8963f3d62f3565d295847170bc998d1ec1a70
 DIST gpgme-1.22.0.tar.bz2.sig 119 BLAKE2B fde8892743e7658004d73d89dcb3899fd003ad9222fa47ec0beb29c507917936cd34ade58609cb44c8ed2d2dc0c8e4aba6ac73ed4789d2a375f79055d23c2349 SHA512 20468946e8247dd12991b25a599ee815b2627931fd3886c41b310eea51f058a51cd1584de2292241a225144bf9a1f18b70bb495cb34304879fc294fc95b220ea
 DIST gpgme-1.23.1.tar.bz2 1716825 BLAKE2B 5810bafb2bbea0a44078fdd587fdeae5a2705dac381d6873dd1cdff017a0be7213125846201cdfef510a5802fdc6d86fd2216b17c380ef5f9e30add5edeaa70c SHA512 a82d5de29a38e5cee4042b3891d0a2c265001832e8578ba17b26c48c6d2a4d5919ac9655b4bfb5235dc8c7cea8d3254054da270d287133b9161e7c6ef93b2d58

diff --git a/app-crypt/gpgme/gpgme-1.21.0.ebuild b/app-crypt/gpgme/gpgme-1.21.0.ebuild
deleted file mode 100644
index 14b74f45fbc5..000000000000
--- a/app-crypt/gpgme/gpgme-1.21.0.ebuild
+++ /dev/null
@@ -1,163 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# Maintainers should:
-# 1. Join the "Gentoo" project at https://dev.gnupg.org/project/view/27/
-# 2. Subscribe to release tasks like https://dev.gnupg.org/T6159
-# (find the one for the current release then subscribe to it +
-# any subsequent ones linked within so you're covered for a while.)
-
-DISTUTILS_EXT=1
-DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python3_{10..12} )
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/gnupg.asc
-
-inherit distutils-r1 libtool flag-o-matic qmake-utils toolchain-funcs verify-sig
-
-DESCRIPTION="GnuPG Made Easy is a library for making GnuPG easier to use"
-HOMEPAGE="https://www.gnupg.org/related_software/gpgme"
-SRC_URI="
-	mirror://gnupg/gpgme/${P}.tar.bz2
-	verify-sig? ( mirror://gnupg/gpgme/${P}.tar.bz2.sig )
-"
-
-LICENSE="GPL-2 LGPL-2.1"
-# Please check ABI on each bump, even if SONAMEs didn't change: bug #833355
-# Use e.g. app-portage/iwdevtools integration with dev-libs/libabigail's abidiff.
-# Subslot: SONAME of each: <libgpgme.libgpgmepp.libqgpgme.FUDGE>
-# Bump FUDGE if a release is made which breaks ABI without changing SONAME.
-# (Reset to 0 if FUDGE != 0 if libgpgme/libgpgmepp/libqpggme change.)
-SLOT="1/11.6.15.2"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="common-lisp static-libs +cxx python qt5 test"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="qt5? ( cxx ) python? ( ${PYTHON_REQUIRED_USE} )"
-
-# - On each bump, update dep bounds on each version from configure.ac!
-RDEPEND="
-	>=app-crypt/gnupg-2
-	>=dev-libs/libassuan-2.5.3:=
-	>=dev-libs/libgpg-error-1.36:=
-	>=dev-libs/libgpg-error-1.46-r1
-	python? ( ${PYTHON_DEPS} )
-	qt5? ( dev-qt/qtcore:5 )
-"
-DEPEND="
-	${RDEPEND}
-	test? (
-		qt5? ( dev-qt/qttest:5 )
-	)
-"
-#doc? ( app-doc/doxygen[dot] )
-BDEPEND="
-	python? ( dev-lang/swig )
-	verify-sig? ( sec-keys/openpgp-keys-gnupg )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.18.0-tests-start-stop-agent-use-command-v.patch
-)
-
-src_prepare() {
-	default
-
-	elibtoolize
-
-	# bug #697456
-	addpredict /run/user/$(id -u)/gnupg
-
-	local MAX_WORKDIR=66
-	if use test && [[ "${#WORKDIR}" -gt "${MAX_WORKDIR}" ]]; then
-		eerror "Unable to run tests as WORKDIR='${WORKDIR}' is longer than ${MAX_WORKDIR} which causes failure!"
-		die "Could not run tests as requested with too-long WORKDIR."
-	fi
-
-	# Make best effort to allow longer PORTAGE_TMPDIR
-	# as usock limitation fails build/tests
-	ln -s "${P}" "${WORKDIR}/b" || die
-	S="${WORKDIR}/b"
-}
-
-src_configure() {
-	local languages=()
-
-	# bug #847955
-	append-lfs-flags
-
-	if use common-lisp ; then
-		languages+=( "cl" )
-	fi
-
-	if use cxx ; then
-		languages+=( "cpp" )
-	fi
-
-	# TODO: qt6? but qt5 and qt5 are mutually exclusive :(
-	if use qt5; then
-		languages+=( "qt5" )
-
-		#use doc ||
-		export DOXYGEN=true
-		export MOC="$(qt5_get_bindir)/moc"
-	fi
-
-	local myeconfargs=(
-		$(use test || echo "--disable-gpgconf-test --disable-gpg-test --disable-gpgsm-test --disable-g13-test")
-		--enable-languages="${languages[*]}"
-		$(use_enable static-libs static)
-	)
-
-	econf "${myeconfargs[@]}"
-
-	if use python ; then
-		emake -C lang/python prepare
-
-		pushd lang/python > /dev/null || die
-		top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_configure
-		popd > /dev/null || die
-	fi
-}
-
-src_compile() {
-	default
-
-	if use python ; then
-		pushd lang/python > /dev/null || die
-		top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_compile
-		popd > /dev/null || die
-	fi
-}
-
-src_test() {
-	default
-
-	if use python ; then
-		distutils-r1_src_test
-	fi
-}
-
-python_test() {
-	emake -C lang/python/tests check \
-		PYTHON=${EPYTHON} \
-		PYTHONS=${EPYTHON} \
-		TESTFLAGS="--python-libdir=${BUILD_DIR}/lib"
-}
-
-src_install() {
-	default
-
-	if use python ; then
-		pushd lang/python > /dev/null || die
-		top_builddir="../.." srcdir="." CPP="$(tc-getCPP)" distutils-r1_src_install
-		popd > /dev/null || die
-	fi
-
-	find "${ED}" -type f -name '*.la' -delete || die
-
-	# Backward compatibility for gentoo
-	# (in the past, we had slots)
-	dodir /usr/include/gpgme
-	dosym ../gpgme.h /usr/include/gpgme/gpgme.h
-}