[gentoo-commits] repo/gentoo:master commit in: media-libs/roc-toolkit/

["Sam James" <sam@gentoo.org>]

commit:     4483ff92f3472c95786123bcf1cfe73fc593ed6f
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Nov  5 14:44:55 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Nov  5 14:47:19 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4483ff92

media-libs/roc-toolkit: add 0.2.6

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/roc-toolkit/Manifest                 |  1 +
 media-libs/roc-toolkit/roc-toolkit-0.2.6.ebuild | 82 +++++++++++++++++++++++++
 2 files changed, 83 insertions(+)

diff --git a/media-libs/roc-toolkit/Manifest b/media-libs/roc-toolkit/Manifest
index d79596d5c51a..4522470d3e04 100644
--- a/media-libs/roc-toolkit/Manifest
+++ b/media-libs/roc-toolkit/Manifest
@@ -1 +1,2 @@
 DIST roc-toolkit-0.2.5.tar.gz 1559917 BLAKE2B b75a2f101bd9bfecee28abc1dee0102c55a06f6432d66ed0b982b774e330209cdb9c22db442b9a49ec6e5623193de0c55fdb118a5285fb7de199b85eb6daea48 SHA512 45a524d7c29f2011eaa9f3e6d256ccf714e1abe2921c8ed276d97501cd2f7641bc14288f2f29c892a1c6740cf64049e3d143eb6b15dd2fb14e25a38a4ad23971
+DIST roc-toolkit-0.2.6.tar.gz 1570499 BLAKE2B 6fa38819fc675323585a0bd5f754b7325be0d9870a55b65636498822249fe1d53b23422b7fa6a0b7e7740aff4f7e62fed9b2681741fbd8912ef8ec2bcc375ee4 SHA512 ac0f18e8a8a60ae9e93f3dcb58e645f31440b6799dac063b246f5320978ac98192bb9c38bbfa7e38dbd537da169c1d525d93cf66c86b36976d37932e3c12f63b

diff --git a/media-libs/roc-toolkit/roc-toolkit-0.2.6.ebuild b/media-libs/roc-toolkit/roc-toolkit-0.2.6.ebuild
new file mode 100644
index 000000000000..f154ee0346a5
--- /dev/null
+++ b/media-libs/roc-toolkit/roc-toolkit-0.2.6.ebuild
@@ -0,0 +1,82 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit python-any-r1 scons-utils toolchain-funcs
+
+DESCRIPTION="Real-time audio streaming over the network"
+HOMEPAGE="https://roc-streaming.org/toolkit/docs/ https://github.com/roc-streaming/roc-toolkit/"
+SRC_URI="https://github.com/roc-streaming/roc-toolkit/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="alsa llvm-libunwind pulseaudio sox ssl tools test unwind"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/libuv:=
+	media-libs/openfec
+	media-libs/speexdsp
+	alsa? ( media-libs/alsa-lib )
+	pulseaudio? ( media-libs/libpulse )
+	sox? ( media-sound/sox )
+	ssl? ( dev-libs/openssl:= )
+	unwind? (
+		llvm-libunwind? ( sys-libs/llvm-libunwind:= )
+		!llvm-libunwind? ( sys-libs/libunwind:= )
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-util/ragel
+	virtual/pkgconfig
+	test? ( dev-util/cpputest )
+	tools? ( dev-util/gengetopt )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.2.5-dont-force-O3.patch
+)
+
+src_prepare() {
+	default
+
+	# These tests need network
+	rm -r \
+		src/tests/roc_netio \
+		src/tests/public_api/test_receiver.cpp \
+		|| die
+}
+
+src_compile() {
+	tc-export AR CXX CC LD RANLIB OBJCOPY PKG_CONFIG
+
+	# Can revisit these on request, but:
+	#
+	# * openfec is unconditionally enabled as upstream docs recommend it,
+	# see https://roc-streaming.org/toolkit/docs/building/user_cookbook.html.
+	#
+	# * speexdsp is unconditionally enabled as it's tiny.
+	scons_opts=(
+		$(usev !alsa '--disable-alsa')
+		$(usev !sox '--disable-sox')
+		$(usev !pulseaudio '--disable-pulseaudio')
+		$(usev !tools '--disable-tools')
+		$(usev test '--enable-tests')
+		$(usev !ssl '--disable-openssl')
+		$(usev !unwind '--disable-libunwind')
+	)
+
+	STRIP=true escons "${scons_opts[@]}"
+}
+
+src_test() {
+	STRIP=true escons "${scons_opts[@]}" test
+}
+
+src_install() {
+	STRIP=true escons DESTDIR="${D}" "${scons_opts[@]}" install
+}