[gentoo-commits] repo/gentoo:master commit in: sci-mathematics/lean/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     0a9f17ccefbfe98fa6b5d3698f412e4def72048b
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 25 20:03:32 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu Oct 26 13:11:35 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0a9f17cc

sci-mathematics/lean: drop old 3.9999

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 sci-mathematics/lean/lean-3.9999.ebuild | 80 ---------------------------------
 1 file changed, 80 deletions(-)

diff --git a/sci-mathematics/lean/lean-3.9999.ebuild b/sci-mathematics/lean/lean-3.9999.ebuild
deleted file mode 100644
index 72a23985077c..000000000000
--- a/sci-mathematics/lean/lean-3.9999.ebuild
+++ /dev/null
@@ -1,80 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-MAJOR=$(ver_cut 1)
-CMAKE_IN_SOURCE_BUILD="ON"
-
-inherit flag-o-matic cmake readme.gentoo-r1
-
-DESCRIPTION="The Lean Theorem Prover"
-HOMEPAGE="https://leanprover-community.github.io/"
-
-if [[ ${PV} == *9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/leanprover-community/lean.git"
-else
-	SRC_URI="https://github.com/leanprover-community/lean/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-fi
-S="${S}/src"
-
-LICENSE="Apache-2.0"
-SLOT="0/${MAJOR}"
-IUSE="debug +threads"
-
-RDEPEND="dev-libs/gmp:="
-DEPEND="${RDEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-3.50.3-gcc-13.patch
-	"${FILESDIR}"/${PN}-CMakeLists-fix_flags.patch
-)
-
-src_configure() {
-	local CMAKE_BUILD_TYPE
-	if use debug; then
-		CMAKE_BUILD_TYPE="Debug"
-	else
-		CMAKE_BUILD_TYPE="Release"
-	fi
-
-	filter-lto
-
-	local -a mycmakeargs=(
-		-DALPHA=ON
-		-DAUTO_THREAD_FINALIZATION=ON
-		-DJSON=ON  # bug 833900
-		-DLEAN_EXTRA_CXX_FLAGS="${CXXFLAGS}"
-		-DMULTI_THREAD=$(usex threads)
-		-DUSE_GITHASH=OFF
-	)
-	cmake_src_configure
-}
-
-src_test() {
-	local -a myctestargs=(
-		# Disable problematic "style_check" cpplint test,
-		# this also removes the python test dependency
-		--exclude-regex style_check
-	)
-	cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	local DISABLE_AUTOFORMATTING="yes"
-	local DOC_CONTENTS="You probably want to use lean with mathlib, you can either:
-	- Do not install mathlib globally and use local versions
-	- Use leanproject from sci-mathematics/mathlib-tools
-		$ leanproject global-install
-	- Use leanpkg and compile mathlib (which will take some time)
-		$ leanpkg install https://github.com/leanprover-community/mathlib"
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-}