[gentoo-commits] repo/gentoo:master commit in: x11-terms/kitty/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     8de108910075a751b5fc182f635a85fea5fbbb78
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 25 07:06:13 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Wed Oct 25 07:56:14 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8de10891

x11-terms/kitty: drop 0.29.2-r1

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 x11-terms/kitty/Manifest               |   3 -
 x11-terms/kitty/kitty-0.29.2-r1.ebuild | 166 ---------------------------------
 2 files changed, 169 deletions(-)

diff --git a/x11-terms/kitty/Manifest b/x11-terms/kitty/Manifest
index 468feec92331..2b17be259b31 100644
--- a/x11-terms/kitty/Manifest
+++ b/x11-terms/kitty/Manifest
@@ -1,6 +1,3 @@
-DIST kitty-0.29.2-vendor.tar.xz 1377044 BLAKE2B f342c7be9bec556b9b16b0e2032ac1ec80296f791a0c55d8b0831d8e148f05e2a7e1ae7c30090c70e7da7e6ca489e5b9b013f59d35af708eff073899f345b7ac SHA512 c0e2c55b0c7ca6ad435092c1267ed1164e042cc61ebf80b298477703607ac7611170cac1918d3703669e2363756e2d805d490018e66cc5b97efecbd0e516298e
-DIST kitty-0.29.2.tar.xz 7809388 BLAKE2B 6928d79a6cc0eaac4d92ce3babbeb0a42bf1dbc92b775386b521c8399352ba77ab9828f8cfd9f40c3e4f29ae98852b6f3cb9ee1f412474ba2ef655c18d2c294d SHA512 a34d8b5bc817dd9d27f1afa190856d916576f52458ede2253655b294358b6b89b1f103acb90d8d66a494b346420ddedc9fcf1a3399f561268ded82e7b1954b06
-DIST kitty-0.29.2.tar.xz.sig 566 BLAKE2B 52fe246f3c4a74dfb62ed34b12b639858eb91aef02c872e472e1a1272268f6da2027b325dc29e260346c76bfbaa206486c6ce2f44f259d33f1ca3a0fd82150ff SHA512 ffcc63904a09148ddbf2eb761686942d1de3ce2c8c7c93b8a1c59ef704e0886bce972dd162e88de65912682233b21398970685cebbda785f7c4215f02ddbf9fd
 DIST kitty-0.30.1-vendor.tar.xz 1425096 BLAKE2B dcf65787badf2439b5e7dc9ff1fb2073d0d8b124a7c39e017aee70a9c5c8f9b5f75b9c7942748cdd7327c75e506d667736eb13d91d8c42f46dfff12ffb9ae4d9 SHA512 4cabb39c82b4dfde96390bfd739d24af3abc6a48f2f6013fb51a1d95d31b04c545f8dbf0d3fc89bcb692c26955bdefe196e95d41eed7222eb815b3f05688a362
 DIST kitty-0.30.1.tar.xz 7799076 BLAKE2B 99ada03fa957819e716d3225fbee20af62135ff8861d3a6ce8aaf442b4526a69f34dae0ec126db48a4336fcbd2dfde5583e2ff8f16140e938fada6c0a8854a60 SHA512 e5fd68b8acf3eae8f53a2c27101d998eb0d8eff1571de1b03ab431bceafcab0efae821590684ec48b5ed6e3d86fb984d9e04784022ba50c0378d37a68598f9ed
 DIST kitty-0.30.1.tar.xz.sig 566 BLAKE2B 18ad4df3ef3e161d8382f635f371b0100ff812d3eb2d5d1a2af1df2e04d1c15a344e4dd86d6a8faaf663a6a9d579521cdacdf6c5b1852d2120d94c43cd765826 SHA512 8c90733cb1683f6cb7c57fcf1efdbd0a99b16c4e1edca9b7e99820e5108694fcee521fecd7adaecc331a744b04d2041594adbf058d6218cd82099550f04b961e

diff --git a/x11-terms/kitty/kitty-0.29.2-r1.ebuild b/x11-terms/kitty/kitty-0.29.2-r1.ebuild
deleted file mode 100644
index 5399ebaefc11..000000000000
--- a/x11-terms/kitty/kitty-0.29.2-r1.ebuild
+++ /dev/null
@@ -1,166 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-inherit edo optfeature multiprocessing python-single-r1 toolchain-funcs xdg
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
-else
-	inherit verify-sig
-	SRC_URI="
-		https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz
-		https://dev.gentoo.org/~ionen/distfiles/${P}-vendor.tar.xz
-		verify-sig? ( https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz.sig )"
-	KEYWORDS="amd64 ~arm64 ~ppc64 ~riscv x86"
-fi
-
-DESCRIPTION="Fast, feature-rich, GPU-based terminal"
-HOMEPAGE="https://sw.kovidgoyal.net/kitty/"
-
-LICENSE="GPL-3 ZLIB"
-LICENSE+=" Apache-2.0 BSD MIT MPL-2.0" # go
-SLOT="0"
-IUSE="+X test wayland"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( X wayland )
-	test? ( X wayland )"
-RESTRICT="!test? ( test )"
-
-# dlopen: fontconfig,libglvnd
-RDEPEND="
-	${PYTHON_DEPS}
-	dev-libs/openssl:=
-	media-libs/fontconfig
-	media-libs/harfbuzz:=[truetype]
-	media-libs/lcms:2
-	media-libs/libglvnd[X?]
-	media-libs/libpng:=
-	net-libs/librsync:=
-	sys-apps/dbus
-	sys-libs/zlib:=
-	x11-libs/libxkbcommon[X?]
-	x11-misc/xkeyboard-config
-	~x11-terms/kitty-shell-integration-${PV}
-	~x11-terms/kitty-terminfo-${PV}
-	X? ( x11-libs/libX11 )
-	wayland? ( dev-libs/wayland )
-	!sci-mathematics/kissat"
-DEPEND="
-	${RDEPEND}
-	X? (
-		x11-base/xorg-proto
-		x11-libs/libXcursor
-		x11-libs/libXi
-		x11-libs/libXinerama
-		x11-libs/libXrandr
-	)
-	wayland? ( dev-libs/wayland-protocols )"
-BDEPEND="
-	${PYTHON_DEPS}
-	>=dev-lang/go-1.20
-	sys-libs/ncurses
-	virtual/pkgconfig
-	test? ( $(python_gen_cond_dep 'dev-python/pillow[${PYTHON_USEDEP}]') )
-	wayland? ( dev-util/wayland-scanner )"
-[[ ${PV} == 9999 ]] || BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-kovidgoyal )"
-
-QA_FLAGS_IGNORED="usr/bin/kitten" # written in Go
-
-src_unpack() {
-	if [[ ${PV} == 9999 ]]; then
-		git-r3_src_unpack
-		cd "${S}" || die
-		edo go mod vendor
-	else
-		if use verify-sig; then
-			local VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/kovidgoyal.gpg
-			verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
-		fi
-		default
-	fi
-}
-
-src_prepare() {
-	default
-
-	# sed unfortunately feels easier on maintenance than patches here
-	local sedargs=(
-		-e "/num_workers =/s/=.*/= $(makeopts_jobs)/"
-		-e "s/cflags.append.*-O3.*/pass/" -e 's/-O3//'
-		-e "s/ld_flags.append('-[sw]')/pass/"
-	)
-
-	# kitty is often popular on wayland-only setups, try to allow this
-	use !X && sedargs+=( -e '/gl_libs =/s/=.*/= []/' ) #857918
-	use !X || use !wayland &&
-		sedargs+=( -e "s/'x11 wayland'/'$(usex X x11 wayland)'/" )
-
-	# skip docs for live version, missing dependencies
-	[[ ${PV} == 9999 ]] && sedargs+=( -e '/exists.*_build/,/docs(ddir)/d' )
-
-	sed -i setup.py "${sedargs[@]}" || die
-
-	local skiptests=(
-		# relies on 'who' command which doesn't detect users with pid-sandbox
-		kitty_tests/utmp.py
-		# may fail/hang depending on environment and shell initialization
-		kitty_tests/{shell_integration,ssh}.py
-		# relies on /proc/self/fd and gets confused when ran from here
-		tools/utils/tpmfile_test.go
-	)
-	use !test || rm "${skiptests[@]}" || die
-}
-
-src_compile() {
-	tc-export CC
-	local -x GOFLAGS="-p=$(makeopts_jobs) -v -x"
-	use ppc64 && [[ $(tc-endian) == big ]] || GOFLAGS+=" -buildmode=pie"
-	local -x PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
-
-	local conf=(
-		--disable-link-time-optimization
-		--ignore-compiler-warnings
-		--libdir-name=$(get_libdir)
-		--shell-integration="enabled no-rc"
-		--update-check-interval=0
-		--verbose
-	)
-
-	edo "${EPYTHON}" setup.py linux-package "${conf[@]}"
-	use test && edo "${EPYTHON}" setup.py build-launcher "${conf[@]}"
-
-	rm -r linux-package/share/terminfo || die # provided by kitty-terminfo
-
-	if [[ ${PV} == 9999 ]]; then
-		mkdir -p linux-package/share/doc/${PF} || die
-	else
-		mv linux-package/share/doc/{${PN},${PF}} || die
-	fi
-
-	# generate default config as reference, command taken from docs/conf.rst
-	if ! tc-is-cross-compiler; then
-		linux-package/bin/kitty +runpy \
-			'from kitty.config import *; print(commented_out_default_config())' \
-			> linux-package/share/doc/${PF}/kitty.conf || die
-	fi
-}
-
-src_test() {
-	KITTY_CONFIG_DIRECTORY=${T} ./test.py || die # shebang is kitty
-}
-
-src_install() {
-	edo mv linux-package "${ED}"/usr
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "audio-based terminal bell support" media-libs/libcanberra
-	optfeature "opening links from the terminal" x11-misc/xdg-utils
-}