[gentoo-commits] repo/gentoo:master commit in: app-misc/tracker-miners/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     e0c5015ce4fab45df7b7164ca036840e5a2665c6
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 21 22:04:20 2023 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Oct 21 22:04:39 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0c5015c

app-misc/tracker-miners: drop 3.6.0

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-misc/tracker-miners/Manifest                   |   1 -
 .../tracker-miners/tracker-miners-3.6.0.ebuild     | 177 ---------------------
 2 files changed, 178 deletions(-)

diff --git a/app-misc/tracker-miners/Manifest b/app-misc/tracker-miners/Manifest
index e160ec22423b..c9f698e5ff80 100644
--- a/app-misc/tracker-miners/Manifest
+++ b/app-misc/tracker-miners/Manifest
@@ -1,4 +1,3 @@
 DIST tracker-miners-3.5.2.tar.xz 7513024 BLAKE2B 6f144bb5e263c08c32b940dd18f98faa4201cfa1c40fa9c97b7e0406b6ed1c9547b1925337e0b3a7e5448dd7c2518b78f62e04e5beab221a55f464506baa151b SHA512 adb29549c94c68a46e2c5ede8a51bac2d014f772a5dc1c63f5cc6950da7f941e735bf5858c3306d2ad988ce2f60126bc97e5db746afe757b9b7cbc4f90518648
 DIST tracker-miners-3.5.3.tar.xz 7513760 BLAKE2B 5241cdd1265a2d90a85870c6e2c6e34fd447e0baf73224c159d9d2998f97a001fb52473b60ad9623af2f874638a182b1edfebad61788b60ba16c21b7e8ce661a SHA512 9855b667d6bf47e1739ae2118e54c299274b23624f54ea5ccbfcbde790a2fc817fee8d95e112ffb7b0de39faa304182845c1aa40f2ac0531e37a090f7cdcec63
-DIST tracker-miners-3.6.0.tar.xz 7506144 BLAKE2B bb223fce64901580bf33970fe350692f578d35b5fdb5f1d8bcdf3dcd8a0b0aaac083de60f90d6c4a5aa810b8912971a75517309e75d252c3772997f0d7ec2f0b SHA512 c56c182ee2200d8d264826d77ccc0f22fd1d27bf0953dbdf75538ab70981707fb384943f77db632c202a54ae3b990a9c852a619172c701e14288b7c4f4c70917
 DIST tracker-miners-3.6.1.tar.xz 7506716 BLAKE2B 73791820082611023f0a275eca0b92eea8cbbf56cd198143c43f1d9be4b47c2004de081618767dd8a929d899b4fa19128d1ddb2c03988b86c7b638b59cab6c09 SHA512 08685983e6ffd9b6ce435465e8996c07fd83775c0f00cafa991fbb1bda6227bb6ef52cfad7ebc9fa5854b06c4ee15d6f94dc81192efa9e9d798f22cee404026f

diff --git a/app-misc/tracker-miners/tracker-miners-3.6.0.ebuild b/app-misc/tracker-miners/tracker-miners-3.6.0.ebuild
deleted file mode 100644
index d4adb19cc0c5..000000000000
--- a/app-misc/tracker-miners/tracker-miners-3.6.0.ebuild
+++ /dev/null
@@ -1,177 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-PYTHON_COMPAT=( python3_{10..12} )
-
-inherit flag-o-matic gnome.org gnome2-utils meson python-any-r1 systemd xdg
-
-DESCRIPTION="Collection of data extractors for Tracker/Nepomuk"
-HOMEPAGE="https://wiki.gnome.org/Projects/Tracker"
-
-LICENSE="GPL-2+ LGPL-2.1+"
-SLOT="3"
-IUSE="cue exif ffmpeg gif gsf +gstreamer iptc +iso +jpeg networkmanager +pdf +playlist raw +rss seccomp test +tiff upower +xml xmp xps"
-
-REQUIRED_USE="cue? ( gstreamer )" # cue is currently only supported via gstreamer, not ffmpeg
-RESTRICT="!test? ( test )"
-
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
-
-# tracker-2.1.7 currently always depends on ICU (theoretically could be libunistring instead);
-# so choose ICU over enca always here for the time being (ICU is preferred)
-RDEPEND="
-	>=dev-libs/glib-2.70:2
-	>=app-misc/tracker-3.6_rc:3
-
-	>=sys-apps/dbus-1.3.1
-	xmp? ( >=media-libs/exempi-2.1.0:= )
-	raw? ( media-libs/gexiv2 )
-	cue? ( media-libs/libcue:= )
-	exif? ( >=media-libs/libexif-0.6 )
-	gsf? ( >=gnome-extra/libgsf-1.14.24:= )
-	xps? ( app-text/libgxps )
-	iptc? ( media-libs/libiptcdata )
-	jpeg? ( media-libs/libjpeg-turbo:0= )
-	iso? ( >=sys-libs/libosinfo-1.10.0-r1 )
-	>=media-libs/libpng-1.2:0=
-	seccomp? ( >=sys-libs/libseccomp-2.0 )
-	tiff? ( media-libs/tiff:= )
-	xml? ( >=dev-libs/libxml2-2.6 )
-	pdf? ( >=app-text/poppler-0.16.0:=[cairo] )
-	playlist? ( >=dev-libs/totem-pl-parser-3:= )
-	sys-apps/util-linux
-
-	gif? ( media-libs/giflib:= )
-
-	networkmanager? ( net-misc/networkmanager )
-
-	rss? ( >=net-libs/libgrss-0.7:0 )
-	app-arch/gzip
-
-	upower? ( >=sys-power/upower-0.9.0:= )
-
-	>=dev-libs/icu-4.8.1.1:=
-
-	gstreamer? (
-		>=media-libs/gstreamer-1.20:1.0
-		>=media-libs/gst-plugins-base-1.20:1.0
-		>=media-plugins/gst-plugins-meta-1.20:1.0 )
-	!gstreamer? (
-		ffmpeg? ( media-video/ffmpeg:0= ) )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	app-text/asciidoc
-	dev-libs/libxslt
-	dev-util/glib-utils
-	dev-util/gdbus-codegen
-
-	>=sys-devel/gettext-0.19.8
-	virtual/pkgconfig
-	test? (
-		${PYTHON_DEPS}
-		$(python_gen_any_dep 'dev-python/pygobject[${PYTHON_USEDEP}]')
-		$(python_gen_any_dep 'dev-python/tappy[${PYTHON_USEDEP}]')
-		gstreamer? (
-			media-libs/gstreamer:1.0[introspection]
-			|| (
-				media-plugins/gst-plugins-libav:1.0
-				media-plugins/gst-plugins-openh264:1.0
-			)
-		)
-	)
-"
-
-python_check_deps() {
-	python_has_version -b \
-		"dev-python/pygobject[${PYTHON_USEDEP}]" \
-		"dev-python/tappy[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# Avoid gst-inspect calls that may trigger sandbox;
-	# instead assume the detection will succeed and add the needed test deps for that
-	if use gstreamer; then
-		sed -i -e 's:detect-h264-codec.sh:/bin/true:' tests/functional-tests/meson.build || die
-	else
-		sed -i -e 's:detect-h264-codec.sh:/bin/false:' tests/functional-tests/meson.build || die
-	fi
-	gnome2_environment_reset # sets gstreamer safety variables
-}
-
-src_configure() {
-	append-cflags -DTRACKER_DEBUG -DG_DISABLE_CAST_CHECKS
-
-	local media_extractor="none"
-	if use gstreamer ; then
-		media_extractor="gstreamer"
-	elif use ffmpeg ; then
-		media_extractor="libav"
-	fi
-
-	local emesonargs=(
-		-Dtracker_core=system
-
-		-Dman=true
-		-Dextract=true
-		$(meson_use test functional_tests)
-		$(meson_use test tests_tap_protocol)
-		-Dminer_fs=true
-		$(meson_use rss miner_rss)
-		-Dwriteback=true
-		-Dabiword=true
-		-Dicon=true
-		-Dmp3=true
-		-Dps=true
-		-Dtext=true
-		-Dunzip_ps_gz_files=true # spawns gunzip
-
-		$(meson_feature networkmanager network_manager)
-		$(meson_feature cue)
-		$(meson_feature exif)
-		$(meson_feature gif)
-		$(meson_feature gsf)
-		$(meson_feature iptc)
-		$(meson_feature iso)
-		$(meson_feature jpeg)
-		$(meson_feature pdf)
-		$(meson_feature playlist)
-		-Dpng=enabled
-		$(meson_feature raw)
-		$(meson_feature tiff)
-		$(meson_feature xml)
-		$(meson_feature xmp)
-		$(meson_feature xps)
-
-		-Dbattery_detection=$(usex upower upower none)
-		# enca is a possibility, but right now we have tracker core always dep on icu and icu is preferred over enca
-		-Dcharset_detection=icu
-		-Dgeneric_media_extractor=${media_extractor}
-		# gupnp gstreamer_backend is in bad state, upstream suggests to use discoverer, which is the default
-		-Dsystemd_user_services_dir="$(systemd_get_userunitdir)"
-	)
-	meson_src_configure
-}
-
-src_test() {
-	export GSETTINGS_BACKEND="dconf" # Tests require dconf and explicitly check for it (env_reset set it to "memory")
-	export PYTHONPATH="${EROOT}"/usr/$(get_libdir)/tracker-3.0
-	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	gnome2_schemas_update
-}
-
-pkg_postrm() {
-	xdg_pkg_postrm
-	gnome2_schemas_update
-}