[gentoo-commits] repo/gentoo:master commit in: dev-python/pylatex/

["Michał Górny" <mgorny@gentoo.org>]

commit:     404d0c22a839dd91ed536238a951861def5f58c6
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 20 04:24:48 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 20 04:41:43 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=404d0c22

dev-python/pylatex: Bump to 1.4.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pylatex/Manifest             |  1 +
 dev-python/pylatex/pylatex-1.4.2.ebuild | 69 +++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-python/pylatex/Manifest b/dev-python/pylatex/Manifest
index a532a7052bb2..1b21a4292d95 100644
--- a/dev-python/pylatex/Manifest
+++ b/dev-python/pylatex/Manifest
@@ -1 +1,2 @@
+DIST PyLaTeX-1.4.2.gh.tar.gz 307158 BLAKE2B bc20478759fc8315fd7fa2161d1638035c0dad4731c4cb254c78dfc45da2b361b3864d2ec04d6eb8fd7947e9908610eb0104444edff95666abba6a9f6da4cb4b SHA512 dcbe58de0ab715d6fbb571a7ad3981c875eacd08d06244b8715fa240df6f8f072417ae076a5caee204e000bf7eb55097b9ba49eddb5ce666470e494c15aa88ed
 DIST pylatex-1.4.1.tar.gz 301482 BLAKE2B c68c8bbf70c5099b3c3146922afe94dcf4f90bfc8644fa165ee27835f4a24642645f9849f2f9fd69656dc07dcc4807869275aacf33a1e5b9c59e539801f8e821 SHA512 55a5734e4d239cef4bcaafa0ba64eea013ba3e86d137de5a5f8311d70c949d783e2e7aad24d39d16a6febbe4bddc34e47248068e1328fe3f95f39a7c7019a3a9

diff --git a/dev-python/pylatex/pylatex-1.4.2.ebuild b/dev-python/pylatex/pylatex-1.4.2.ebuild
new file mode 100644
index 000000000000..64beb6cf7322
--- /dev/null
+++ b/dev-python/pylatex/pylatex-1.4.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature
+
+MY_P="PyLaTeX-${PV}"
+DESCRIPTION="A Python library for creating LaTeX files and snippets"
+HOMEPAGE="
+	https://github.com/JelteF/PyLaTeX/
+	https://pypi.org/project/PyLaTeX/
+"
+SRC_URI="
+	https://github.com/JelteF/PyLaTeX/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/ordered-set[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/quantities[${PYTHON_USEDEP}]
+		app-text/texlive
+		dev-texlive/texlive-latexextra
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# bug 798381
+	sed -i -e 's:description-file:description_file:' setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	if use examples ; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/"${PF}"/examples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "compiling generated files" "
+		app-text/texlive
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-mathscience
+	"
+	optfeature "matplotlib support" dev-python/matplotlib
+	optfeature "numpy support" dev-python/numpy
+	optfeature "quantities support" dev-python/quantities
+}