[gentoo-commits] repo/gentoo:master commit in: dev-python/jsonschema-path/, profiles/features/wd40/

[gentoo-commits] repo/gentoo:master commit in: dev-python/jsonschema-path/, profiles/features/wd40/

[Michał Górny]

commit:     5a217f4c14ed4c09bf72e68fe0fb09e6be820e7f
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 13 15:42:37 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 13 15:49:08 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a217f4c

dev-python/jsonschema-path: New package, v0.3.1

This is a API-breaking rename of dev-python/jsonschema-spec, sigh.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/jsonschema-path/Manifest                |  1 +
 .../jsonschema-path/jsonschema-path-0.3.1.ebuild   | 44 ++++++++++++++++++++++
 dev-python/jsonschema-path/metadata.xml            | 13 +++++++
 profiles/features/wd40/package.mask                |  1 +
 4 files changed, 59 insertions(+)

diff --git a/dev-python/jsonschema-path/Manifest b/dev-python/jsonschema-path/Manifest
new file mode 100644
index 000000000000..025b4393a848
--- /dev/null
+++ b/dev-python/jsonschema-path/Manifest
@@ -0,0 +1 @@
+DIST jsonschema-path-0.3.1.gh.tar.gz 39698 BLAKE2B b56f3c6c591066781c01ab32674c8fdd6193352208fbe9a3b06cae6e345711532a4abfb3f4433481eeb02a4dc7e884cc280c1b6d247ee1e647d503cea434b4f6 SHA512 00aa61aacb92d3aa11be6b3f5f69f6cb70743559849c425549a6fcc0c8c6eeff9feaef5a07da70308cc03311ca48dda7e35d429fa2a5a1aba9099fe678594038

diff --git a/dev-python/jsonschema-path/jsonschema-path-0.3.1.ebuild b/dev-python/jsonschema-path/jsonschema-path-0.3.1.ebuild
new file mode 100644
index 000000000000..364da459eeca
--- /dev/null
+++ b/dev-python/jsonschema-path/jsonschema-path-0.3.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="JSONSchema Spec with object-oriented paths"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema-path/
+	https://github.com/p1c2u/jsonschema-path/
+"
+SRC_URI="
+	https://github.com/p1c2u/jsonschema-path/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pathable-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/referencing-0.28.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	# remove random pins due to caret operator
+	sed -i -e 's:\^:>=:' -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}

diff --git a/dev-python/jsonschema-path/metadata.xml b/dev-python/jsonschema-path/metadata.xml
new file mode 100644
index 000000000000..ab4cdeab8d51
--- /dev/null
+++ b/dev-python/jsonschema-path/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">jsonschema-path</remote-id>
+		<remote-id type="github">p1c2u/jsonschema-path</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/profiles/features/wd40/package.mask b/profiles/features/wd40/package.mask
index 1c0a9d95a178..380f8480fdd8 100644
--- a/profiles/features/wd40/package.mask
+++ b/profiles/features/wd40/package.mask
@@ -28,6 +28,7 @@ dev-python/inflect
 dev-python/jaraco-itertools
 dev-python/josepy
 >=dev-python/jsonschema-4.18.0
+dev-python/jsonschema-path
 dev-python/jsonschema-spec
 dev-python/jsonschema-specifications
 >=dev-python/jupyter-events-0.7.0