[gentoo-commits] repo/gentoo:master commit in: net-analyzer/wireshark/

["Sam James" <sam@gentoo.org>]

commit:     33b6c5807156cea1f6c61b5e61c1800e2f649611
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  6 04:08:16 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Oct  6 04:08:30 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=33b6c580

net-analyzer/wireshark: drop 4.0.9

4.0.9 was a short-lived release. use 4.0.10.

Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-analyzer/wireshark/Manifest               |   2 -
 net-analyzer/wireshark/wireshark-4.0.9.ebuild | 341 --------------------------
 2 files changed, 343 deletions(-)

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 08df83e70bb9..a8f348ed9664 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -1,7 +1,5 @@
 DIST wireshark-4.0.10-signatures.txt 2521 BLAKE2B 14ff83e9514b611909a010f750f904c735bc11ecb9fb7f3faebe8e27655c981f8ec9e20481775257c5aa28a1f67e87a708ae4fc0eb6032ebc5c422c1f8ba9e9e SHA512 16dab47407ec56a8e6672404feb50b1a0af7a9e71e761488ad803d6b0c96195edd74387be6b410a40b40c5908923d13d74612228361e3aa388aef0d931ffa023
 DIST wireshark-4.0.10.tar.xz 43124192 BLAKE2B f5121ae15df79d7d8e1bf6f65e566a556b848f623e876a3d6e92a501074e987aaa08a0056be5b42131518e89e0d358efd450f6b8399313cf836883ed345dde48 SHA512 695a5617100195aad92ecc38a29c3b765018fee49913dd6025b2e19d1ec5c5c4ed4195a79b5caa9cf0e8476db237e74bb602e56e9d2989ae852298767eaffbe5
 DIST wireshark-4.0.8.tar.xz 43123664 BLAKE2B bda31be809724a39e475489eb5653589310ae679933fac193cbc8bb3924b3ec48a93b5da6d39655fdb9f4a8d717b9cc84fcb357bea275cb457b45783a75ca778 SHA512 f6de0f86bb1eac82f7ed2d98d7f4fe3189107b1f0da441abd9077593f8e624989c33aaf8b4ef4b3c460fe787c64c4b8fdb3168de9f5661802fed6b06d71c5c65
-DIST wireshark-4.0.9-signatures.txt 2503 BLAKE2B 830d4630826bbf644c3d0b1dbb5df32ba460448c59b07a307987d68354305c6fbe6c4700a38abe493f80883d90425bf9ec330f4155006fca4d1bff37f42df6dd SHA512 d813145850e13a3c77e2edba66f3606667b685d657b04e4ee5bc3b1f6d26a50fb492a2de91447ad07dd358a7c3bbe2b2ccd30ade30da943071daabd006eddffb
-DIST wireshark-4.0.9.tar.xz 43130608 BLAKE2B 9a7760711e761f382496123ca4578a0e6b834de85999a908f24e16ac48ebd3f3ea17e8c29d422f13f67b168ac7accb2cd394a78714b3c543077909a40029a660 SHA512 4700f41f38f23801267c035557b27c151b718542e830460ab895c87d976c44606397b98b9d48b72a7cdd3917aa744794cbccac5babbb6de94a7bd59e8d91e1f0
 DIST wireshark-4.1.0-signatures.txt 2706 BLAKE2B bcc55c14a68aead0061041e39114a04531440d98b24e271d731ff6baa0047adac7871f0e089b326d29273bad71f8fa9fa482ebac21ba7635e9a251831d387a34 SHA512 ae0eb7a36f554d27fecd47cb471f3c85b8bd53030a6dc872f74b33a46eee004910a3c095c16d8eed56a7c2e6104084e632580b555f29e77a4b8c04c50b53019a
 DIST wireshark-4.1.0.tar.xz 44601140 BLAKE2B c20a0a917c94554d593986e9058cee7f10c68a0e73a3b8a69e87c40f5932d4f33da1d3ba8ed5177094058bd43ba9942b21a2f3fe6e04a751ffb75e9e9b524627 SHA512 d3253d26d53dbeaa14f7d7dd0956124de3f7fe1d683f2041c6d1420271ba9601248c904a0927160194ca54aa8752526bd5de643d553e55ded8478caa54cd9bb0

diff --git a/net-analyzer/wireshark/wireshark-4.0.9.ebuild b/net-analyzer/wireshark/wireshark-4.0.9.ebuild
deleted file mode 100644
index b93870af7ae4..000000000000
--- a/net-analyzer/wireshark/wireshark-4.0.9.ebuild
+++ /dev/null
@@ -1,341 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{1..2} )
-PYTHON_COMPAT=( python3_{10..11} )
-
-inherit fcaps flag-o-matic readme.gentoo-r1 lua-single python-any-r1 qmake-utils xdg cmake
-
-DESCRIPTION="Network protocol analyzer (sniffer)"
-HOMEPAGE="https://www.wireshark.org/"
-
-if [[ ${PV} == *9999* ]] ; then
-	EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark"
-	inherit git-r3
-else
-	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
-	inherit verify-sig
-
-	SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
-	SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV}.txt -> ${P}-signatures.txt )"
-	S="${WORKDIR}/${P/_/}"
-
-	if [[ ${PV} != *_rc* ]] ; then
-		KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~riscv ~x86"
-	fi
-fi
-
-LICENSE="GPL-2"
-SLOT="0/${PV}"
-IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
-IUSE+=" +dumpcap +editcap +gui http2 ilbc kerberos libxml2 lto lua lz4 maxminddb"
-IUSE+=" +mergecap +minizip +netlink opus +plugins +pcap qt6 +randpkt"
-IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
-IUSE+=" sdjournal test +text2pcap tfshark +tshark +udpdump wifi zlib +zstd"
-
-REQUIRED_USE="
-	lua? ( ${LUA_REQUIRED_USE} )
-"
-
-# Tests restricted for now because rely on pytest internals w/ >=3.11
-# See bug #897078 and https://gitlab.com/wireshark/wireshark/-/issues/18740.
-RESTRICT="!test? ( test ) test"
-
-# bug #753062 for speexdsp
-RDEPEND="
-	acct-group/pcap
-	>=dev-libs/glib-2.50.0:2
-	dev-libs/libpcre2
-	>=net-dns/c-ares-1.13.0:=
-	>=dev-libs/libgcrypt-1.8.0:=
-	media-libs/speexdsp
-	bcg729? ( media-libs/bcg729 )
-	brotli? ( app-arch/brotli:= )
-	ciscodump? ( >=net-libs/libssh-0.6:= )
-	filecaps? ( sys-libs/libcap )
-	http2? ( >=net-libs/nghttp2-1.11.0:= )
-	ilbc? ( media-libs/libilbc:= )
-	kerberos? ( virtual/krb5 )
-	libxml2? ( dev-libs/libxml2 )
-	lua? ( ${LUA_DEPS} )
-	lz4? ( app-arch/lz4:= )
-	maxminddb? ( dev-libs/libmaxminddb:= )
-	minizip? ( sys-libs/zlib[minizip] )
-	netlink? ( dev-libs/libnl:3 )
-	opus? ( media-libs/opus )
-	pcap? ( net-libs/libpcap )
-	gui? (
-		x11-misc/xdg-utils
-		qt6? (
-			dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
-			dev-qt/qt5compat:6
-			dev-qt/qtmultimedia:6
-		)
-		!qt6? (
-			dev-qt/qtcore:5
-			dev-qt/qtconcurrent:5
-			dev-qt/qtgui:5
-			dev-qt/qtmultimedia:5
-			dev-qt/qtprintsupport:5
-			dev-qt/qtwidgets:5
-		)
-	)
-	sbc? ( media-libs/sbc )
-	sdjournal? ( sys-apps/systemd:= )
-	smi? ( net-libs/libsmi )
-	snappy? ( app-arch/snappy:= )
-	spandsp? ( media-libs/spandsp:= )
-	sshdump? ( >=net-libs/libssh-0.6:= )
-	ssl? ( >=net-libs/gnutls-3.5.8:= )
-	wifi? ( >=net-libs/libssh-0.6:= )
-	zlib? ( sys-libs/zlib )
-	zstd? ( app-arch/zstd:= )
-"
-DEPEND="
-	${RDEPEND}
-	gui? (
-		!qt6? (
-			dev-qt/qtdeclarative:5
-		)
-	)
-"
-# TODO: 4.0.0_rc1 release notes say:
-# "Perl is no longer required to build Wireshark, but may be required to build some source code files and run code analysis checks."
-BDEPEND="
-	${PYTHON_DEPS}
-	dev-lang/perl
-	sys-devel/flex
-	sys-devel/gettext
-	virtual/pkgconfig
-	doc? (
-		app-doc/doxygen
-		dev-ruby/asciidoctor
-	)
-	gui? (
-		qt6? (
-			dev-qt/qttools:6[linguist]
-		)
-		!qt6? (
-			dev-qt/linguist-tools:5
-		)
-	)
-	test? (
-		$(python_gen_any_dep '
-			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		')
-	)
-"
-RDEPEND="
-	${RDEPEND}
-	gui? ( virtual/freedesktop-icon-theme )
-	selinux? ( sec-policy/selinux-wireshark )
-"
-
-if [[ ${PV} != *9999* ]] ; then
-	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
-fi
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.6.0-redhat.patch
-	"${FILESDIR}"/${PN}-3.4.2-cmake-lua-version.patch
-)
-
-python_check_deps() {
-	use test || return 0
-
-	python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
-		 python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-
-	python-any-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} == *9999* ]] ; then
-		git-r3_src_unpack
-	else
-		if use verify-sig ; then
-			cd "${DISTDIR}" || die
-			verify-sig_verify_signed_checksums \
-				${P}-signatures.txt \
-				openssl-dgst \
-				${P}.tar.xz
-			cd "${WORKDIR}" || die
-		fi
-
-		default
-	fi
-}
-
-src_configure() {
-	local mycmakeargs
-
-	python_setup
-
-	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
-	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
-	if use kerberos ; then
-		case $(krb5-config --libs) in
-			*-lcrypto*)
-				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
-				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
-				ewarn "license and the GPL, so do your check before distributing such package."
-				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
-				;;
-		esac
-	fi
-
-	if use gui ; then
-		append-cxxflags -fPIC -DPIC
-	fi
-
-	! use lto && filter-lto
-
-	mycmakeargs+=(
-		-DPython3_EXECUTABLE="${PYTHON}"
-		-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
-
-		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
-		$(usex gui LRELEASE=$(qt5_get_bindir)/lrelease '')
-		$(usex gui MOC=$(qt5_get_bindir)/moc '')
-		$(usex gui RCC=$(qt5_get_bindir)/rcc '')
-		$(usex gui UIC=$(qt5_get_bindir)/uic '')
-
-		-DBUILD_androiddump=$(usex androiddump)
-		-DBUILD_capinfos=$(usex capinfos)
-		-DBUILD_captype=$(usex captype)
-		-DBUILD_ciscodump=$(usex ciscodump)
-		-DBUILD_dftest=$(usex dftest)
-		-DBUILD_dpauxmon=$(usex dpauxmon)
-		-DBUILD_dumpcap=$(usex dumpcap)
-		-DBUILD_editcap=$(usex editcap)
-		-DBUILD_mergecap=$(usex mergecap)
-		-DBUILD_mmdbresolve=$(usex maxminddb)
-		-DBUILD_randpkt=$(usex randpkt)
-		-DBUILD_randpktdump=$(usex randpktdump)
-		-DBUILD_reordercap=$(usex reordercap)
-		-DBUILD_sdjournal=$(usex sdjournal)
-		-DBUILD_sharkd=$(usex sharkd)
-		-DBUILD_sshdump=$(usex sshdump)
-		-DBUILD_text2pcap=$(usex text2pcap)
-		-DBUILD_tfshark=$(usex tfshark)
-		-DBUILD_tshark=$(usex tshark)
-		-DBUILD_udpdump=$(usex udpdump)
-
-		-DBUILD_wireshark=$(usex gui)
-		-DUSE_qt6=$(usex qt6)
-
-		-DENABLE_WERROR=OFF
-		-DENABLE_BCG729=$(usex bcg729)
-		-DENABLE_BROTLI=$(usex brotli)
-		-DENABLE_CAP=$(usex filecaps caps)
-		-DENABLE_GNUTLS=$(usex ssl)
-		-DENABLE_ILBC=$(usex ilbc)
-		-DENABLE_KERBEROS=$(usex kerberos)
-		-DENABLE_LIBXML2=$(usex libxml2)
-		-DENABLE_LTO=$(usex lto)
-		-DENABLE_LUA=$(usex lua)
-		-DENABLE_LZ4=$(usex lz4)
-		-DENABLE_MINIZIP=$(usex minizip)
-		-DENABLE_NETLINK=$(usex netlink)
-		-DENABLE_NGHTTP2=$(usex http2)
-		-DENABLE_OPUS=$(usex opus)
-		-DENABLE_PCAP=$(usex pcap)
-		-DENABLE_PLUGINS=$(usex plugins)
-		-DENABLE_PLUGIN_IFDEMO=OFF
-		-DENABLE_SBC=$(usex sbc)
-		-DENABLE_SMI=$(usex smi)
-		-DENABLE_SNAPPY=$(usex snappy)
-		-DENABLE_SPANDSP=$(usex spandsp)
-		-DBUILD_wifidump=$(usex wifi)
-		-DENABLE_ZLIB=$(usex zlib)
-		-DENABLE_ZSTD=$(usex zstd)
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	cmake_build test-programs
-
-	EPYTEST_DESELECT=(
-		# TODO: investigate
-		suite_follow_multistream.py::case_follow_multistream::test_follow_http2_multistream
-	)
-
-	# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
-	epytest \
-		--disable-capture \
-		--skip-missing-programs=all \
-		--program-path "${BUILD_DIR}"/run
-}
-
-src_install() {
-	cmake_src_install
-
-	# FAQ is not required as is installed from help/faq.txt
-	dodoc AUTHORS ChangeLog NEWS README* doc/randpkt.txt doc/README*
-
-	# install headers
-	insinto /usr/include/wireshark
-	doins "${BUILD_DIR}"/config.h
-
-	# If trying to remove this, try build e.g. libvirt first!
-	# At last check, Fedora is still doing this too.
-	local dir dirs=(
-		epan
-		epan/crypt
-		epan/dfilter
-		epan/dissectors
-		epan/ftypes
-		wiretap
-		wsutil
-		wsutil/wmem
-	)
-
-	for dir in "${dirs[@]}" ; do
-		insinto /usr/include/wireshark/${dir}
-		doins ${dir}/*.h
-	done
-
-	if use gui ; then
-		local s
-
-		for s in 16 32 48 64 128 256 512 1024 ; do
-			insinto /usr/share/icons/hicolor/${s}x${s}/apps
-			newins resources/icons/wsicon${s}.png wireshark.png
-		done
-
-		for s in 16 24 32 48 64 128 256 ; do
-			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
-			newins resources/icons//WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
-		done
-	fi
-
-	if [[ -d "${ED}"/usr/share/appdata ]] ; then
-		rm -r "${ED}"/usr/share/appdata || die
-	fi
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	# Add group for users allowed to sniff.
-	chgrp pcap "${EROOT}"/usr/bin/dumpcap
-
-	if use dumpcap && use pcap ; then
-		fcaps -o 0 -g pcap -m 4710 -M 0710 \
-			cap_dac_read_search,cap_net_raw,cap_net_admin \
-			"${EROOT}"/usr/bin/dumpcap
-	fi
-
-	readme.gentoo_print_elog
-}