[gentoo-commits] repo/gentoo:master commit in: app-emacs/ess/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     30a319f7c035921fddf34049ae2ac06b5d062d0e
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Thu Oct  5 07:42:14 2023 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Thu Oct  5 07:44:02 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30a319f7

app-emacs/ess: Load ess-autoloads instead of ess-site

Update ebuild to EAPI 8.

Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 app-emacs/ess/ess-18.10.2-r3.ebuild | 51 +++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/app-emacs/ess/ess-18.10.2-r3.ebuild b/app-emacs/ess/ess-18.10.2-r3.ebuild
new file mode 100644
index 000000000000..40db5f8b38e5
--- /dev/null
+++ b/app-emacs/ess/ess-18.10.2-r3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="Emacs Speaks Statistics"
+HOMEPAGE="https://ess.r-project.org/"
+SRC_URI="https://ess.r-project.org/downloads/ess/${P}.tgz"
+
+LICENSE="GPL-2+ GPL-3+ Texinfo-manual"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+RESTRICT="test"
+
+BDEPEND="app-text/texi2html
+	virtual/latex-base"
+
+PATCHES=( "${FILESDIR}"/${P}-emacs-28.patch )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	default
+	sed -i -e 's/font-lock-reference-face/font-lock-constant-face/g' \
+		lisp/*.el || die
+}
+
+src_compile() {
+	default
+}
+
+src_install() {
+	emake PREFIX="${ED}/usr" \
+		LISPDIR="${ED}${SITELISP}/ess" \
+		ETCDIR="${ED}${SITEETC}/ess" \
+		DOCDIR="${ED}/usr/share/doc/${PF}" \
+		install
+
+	# Version 18* doesn't install *.el files any more #685978
+	elisp-install ${PN} lisp/*.{el,elc} lisp/obsolete/*.{el,elc}
+	elisp-make-site-file "${SITEFILE}" ${PN} "(load \"ess-autoloads\" nil t)"
+
+	# Most documentation is installed by the package's build system.
+	dodoc ChangeLog *NEWS doc/TODO
+	newdoc doc/ChangeLog ChangeLog-doc
+
+	DOC_CONTENTS="Please see /usr/share/doc/${PF} for the complete
+		documentation. Usage hints are in ${SITELISP}/${PN}/ess-site.el ."
+	readme.gentoo_create_doc
+}