[gentoo-commits] repo/gentoo:master commit in: sys-apps/usbredir/

["Sam James" <sam@gentoo.org>]

commit:     b3a8f24047faec87c0820731de6b8df4e82166b7
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  4 14:12:04 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct  4 15:10:43 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b3a8f240

sys-apps/usbredir: don't redefine _FORTIFY_SOURCE

Closes: https://bugs.gentoo.org/898050
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-apps/usbredir/usbredir-0.13.0-r1.ebuild | 41 +++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/sys-apps/usbredir/usbredir-0.13.0-r1.ebuild b/sys-apps/usbredir/usbredir-0.13.0-r1.ebuild
new file mode 100644
index 000000000000..5c896d3ecb8e
--- /dev/null
+++ b/sys-apps/usbredir/usbredir-0.13.0-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="TCP daemon and set of libraries for usbredir protocol (redirecting USB traffic)"
+HOMEPAGE="https://www.spice-space.org/usbredir.html https://gitlab.freedesktop.org/spice/usbredir"
+SRC_URI="https://gitlab.freedesktop.org/spice/usbredir/-/archive/${P}/${PN}-${P}.tar.bz2"
+S="${WORKDIR}"/usbredir-${P}
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/glib:2
+	virtual/libusb:1
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# This overrides our toolchain default.
+	sed -i -e '/-D_FORTIFY_SOURCE=2/d' meson.build || die
+
+	local emesonargs=(
+		-Dgit_werror=disabled
+		$(meson_feature test tests)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dodoc -r docs/.
+}