[gentoo-commits] repo/gentoo:master commit in: net-irc/irssi/

["Sam James" <sam@gentoo.org>]

commit:     5cb4d2ace29a177ea3e218b9348e458e817ee11c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Oct  3 23:34:10 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Oct  3 23:34:10 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5cb4d2ac

net-irc/irssi: add 1.4.5

Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-irc/irssi/Manifest           |  1 +
 net-irc/irssi/irssi-1.4.5.ebuild | 68 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/net-irc/irssi/Manifest b/net-irc/irssi/Manifest
index 652e54173844..eb9df20f8142 100644
--- a/net-irc/irssi/Manifest
+++ b/net-irc/irssi/Manifest
@@ -1 +1,2 @@
 DIST irssi-1.4.4.tar.xz 1213784 BLAKE2B 5b77ca692130a87228eea05f9a8d2da65a7c483e031d8c12dbd29bb9cd629444aae28bc3ffe0dc862891f59047997a323cea3b4d9d388573d4f06b569abbf950 SHA512 da28ac7a527be301d0615d6d733e4cf4e09bb6d4f5c70bc33ff70e22439a01f197bb5d91b4432ca74d3ac2dbb3235f30d53efc63a4279de8664923c2ccdbdbea
+DIST irssi-1.4.5.tar.xz 1215688 BLAKE2B 573d8552137cb09c152fe0d1f9196c966bc0afb23e8817fed7315a07d2fc36b3ffabf5e8384bb80a48aa24cf57e5d336f40e708a4c9ef6bad3ec8ce10125f196 SHA512 5d80107ad625feb6d2b3ac807f517c5cfeae58986d3fbfe53ea82f2dee70396f5092abdc6ef137c5651e4515e081591079b37f0e428f69990db493cfe14e4f36

diff --git a/net-irc/irssi/irssi-1.4.5.ebuild b/net-irc/irssi/irssi-1.4.5.ebuild
new file mode 100644
index 000000000000..40772b5198b3
--- /dev/null
+++ b/net-irc/irssi/irssi-1.4.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GENTOO_DEPEND_ON_PERL="no"
+inherit perl-module meson
+
+DESCRIPTION="A modular textUI IRC client with IPv6 support"
+HOMEPAGE="https://irssi.org/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+else
+	# Keep for _rc compability
+	MY_P="${P/_/-}"
+
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="otr +perl selinux +proxy"
+
+RDEPEND="
+	>=dev-libs/glib-2.6.0
+	dev-libs/openssl:=
+	sys-libs/ncurses:=
+	otr? (
+		>=dev-libs/libgcrypt-1.2.0:=
+		>=net-libs/libotr-4.1.0
+	)
+	perl? ( dev-lang/perl:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	virtual/pkgconfig"
+RDEPEND+=" selinux? ( sec-policy/selinux-irc )"
+
+src_configure() {
+	local emesonargs=(
+		-Ddocdir="${EPREFIX}"/usr/share/doc/${PF}
+		-Dwith-perl-lib=vendor
+		-Dwith-otr=$(usex otr)
+		-Dwith-proxy=$(usex proxy)
+		-Dwith-perl=$(usex perl)
+
+		# Carried over from autotools (for now?), bug #677804
+		-Ddisable-utf8proc=yes
+		-Dwith-fuzzer=no
+		-Dinstall-glib=no
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	# We don't want perl-module's src_test
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	use perl && perl_delete_localpod
+}