[gentoo-commits] repo/gentoo:master commit in: media-sound/mpfc/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     31924c07f3aedf1c491da6de90ab99b776760107
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Sun Sep 24 16:18:47 2023 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue Sep 26 18:06:10 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=31924c07

media-sound/mpfc: EAPI8 bump, use https

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/33037
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-sound/mpfc/mpfc-1.3.8.1-r5.ebuild | 60 +++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/media-sound/mpfc/mpfc-1.3.8.1-r5.ebuild b/media-sound/mpfc/mpfc-1.3.8.1-r5.ebuild
new file mode 100644
index 000000000000..f182195b0023
--- /dev/null
+++ b/media-sound/mpfc/mpfc-1.3.8.1-r5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Music Player For Console"
+HOMEPAGE="https://mpfc.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa cdda flac gpm mad nls oss static-libs vorbis wav"
+
+RDEPEND="alsa? ( >=media-libs/alsa-lib-0.9.0 )
+	flac? ( media-libs/flac:= )
+	gpm? ( >=sys-libs/gpm-1.19.3 )
+	mad? ( media-libs/libmad )
+	vorbis? ( media-libs/libvorbis )
+	sys-libs/ncurses:=[unicode(+)]
+	dev-libs/icu:="
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-underlinking.patch"
+	"${FILESDIR}/${P}-qa-implicit-declarations.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable alsa)
+		$(use_enable cdda audiocd)
+		$(use_enable flac)
+		$(use_enable gpm)
+		$(use_enable mad mp3)
+		$(use_enable nls)
+		$(use_enable oss)
+		$(use_enable static-libs static)
+		$(use_enable vorbis ogg)
+		$(use_enable wav)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	doins mpfcrc
+
+	# package provides .pc files
+	find "${D}" -name '*.la' -delete || die
+}