[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-contacts/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d21415d969a5482e2d326f69eaaf27cebfc0f0c0
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Tue Sep 19 22:15:26 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Sep 21 14:50:53 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d21415d9

gnome-extra/gnome-contacts: Version bump to 45.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32936
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-contacts/Manifest                |  1 +
 .../gnome-contacts/gnome-contacts-45.0.ebuild      | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index 4bfd0f0f1f4e..25e127ffc354 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1 +1,2 @@
 DIST gnome-contacts-44.0.tar.xz 395540 BLAKE2B 479353667217d0f78d61cbc1dff5ec67c13cf14254fbd258cf34d5b084d65c515426b2ce418bf74350f727a2b1cb6b9a0e4ade150eeabd01b06cecf7792f7a7e SHA512 f25a368317923c46f5700359e3fed86f85a155c58adb275ba7d884975debe78594e1da58a95633a33a281cbc78f41824f4ab38b50ae01f4f9f8e38f3f1906849
+DIST gnome-contacts-45.0.tar.xz 401156 BLAKE2B cce302b780717963083b4b0725d9f5e0fd2ec0eeafabdf247fb2e3a099cde84441563a70b7bdf22efa8f20358baf10be015f1e7524139beb8e6074bd12c28e6d SHA512 691cbd9fc1ff0e9e7a2549f522ea7ef5b73eee976fb48b2b250b8be9775737938d9fd0ffa66374dc20028d764e96605caae1be7c32689371a58ee5e78bd7c28b

diff --git a/gnome-extra/gnome-contacts/gnome-contacts-45.0.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-45.0.ebuild
new file mode 100644
index 000000000000..43292f433bf7
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-45.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+gnome-online-accounts"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	gnome-online-accounts? ( net-libs/gnome-online-accounts[vala] )
+	gnome-extra/evolution-data-server[gtk,vala]
+	>=dev-libs/libportal-0.6:=[vala]
+"
+RDEPEND="
+	>=dev-libs/folks-0.14.0:=[eds]
+	>=dev-libs/libgee-0.10:0.8=
+	>=dev-libs/glib-2.64:2
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.4_alpha:1
+	>=gnome-extra/evolution-data-server-3.42:=[gnome-online-accounts?]
+	>=dev-libs/libportal-0.6:=
+	>=media-gfx/qrencode-4.1.1:=
+	gnome-online-accounts? ( net-libs/gnome-online-accounts:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcamera=true # Ignored
+		-Dmanpage=true
+		-Ddocs=false
+		$(meson_use gnome-online-accounts goa)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}