[gentoo-commits] repo/gentoo:master commit in: dev-python/setuptools-scm/

["Michał Górny" <mgorny@gentoo.org>]

commit:     9129a52cbae43cc28be3737068d2937a14431578
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 21 04:49:56 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Sep 21 05:28:24 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9129a52c

dev-python/setuptools-scm: Bump to 8.0.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/setuptools-scm/Manifest                 |  1 +
 .../setuptools-scm/setuptools-scm-8.0.1.ebuild     | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/setuptools-scm/Manifest b/dev-python/setuptools-scm/Manifest
index 1098d86add27..106559c11ee0 100644
--- a/dev-python/setuptools-scm/Manifest
+++ b/dev-python/setuptools-scm/Manifest
@@ -1 +1,2 @@
+DIST setuptools-scm-8.0.1.tar.gz 71827 BLAKE2B 4011879490a02f5bb8b4fa0292ee696010cca9cb5c322854f2c342b4c02a86f7a31535c3fe7b4e6eab4fb77c90a469714227c1487ee7e1c1d4de3a4db1137b6b SHA512 05c087cbcb8bf2f03d68cf91e5545c25dea85d61d16c26194ade42a5e78a573f1adc4265897998d4b151834e994b3aa32e02a1eb2fa103a4cd1f3c8e3b78d8d4
 DIST setuptools_scm-7.1.0.tar.gz 71904 BLAKE2B be5ae215dadcc290290762b732434258409ecc2d71cdf1332ffe73431effae7cbc33e052a718efd952be79350171ed3e468492fc719bc08750dc23364fb0ee9d SHA512 bd7260672c213db6b8c5842dbb6ac69e69ce040777865c935033971f65d905bd8e6b54e174190a924e452c302e69d4c1de231cbc8f603176ba013a739840dad3

diff --git a/dev-python/setuptools-scm/setuptools-scm-8.0.1.ebuild b/dev-python/setuptools-scm/setuptools-scm-8.0.1.ebuild
new file mode 100644
index 000000000000..cb671ce3fa13
--- /dev/null
+++ b/dev-python/setuptools-scm/setuptools-scm-8.0.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Manage versions by scm tags via setuptools"
+HOMEPAGE="
+	https://github.com/pypa/setuptools_scm/
+	https://pypi.org/project/setuptools-scm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# there's an optional dep on rich for cute logs
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-vcs/git
+		!sparc? (
+			dev-vcs/mercurial
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# the usual nondescript gpg-agent failure
+		testing/test_git.py::test_git_getdate_signed_commit
+
+		# fetching from the Internet
+		testing/test_regressions.py::test_pip_download
+	)
+
+	if has_version dev-python/nose; then
+		EPYTEST_DESELECT+=(
+			# https://bugs.gentoo.org/892639
+			testing/test_integration.py::test_pyproject_support
+		)
+	fi
+
+	epytest
+}