[gentoo-commits] repo/gentoo:master commit in: kde-plasma/kdeplasma-addons/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     a176a024898ca28e68dbb004f3854cf5305f751a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 19 14:49:43 2023 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Sep 19 15:23:16 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a176a024

kde-plasma/kdeplasma-addons: Fix dependencies

Closes: https://bugs.gentoo.org/914140
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kdeplasma-addons-5.27.8-r1.ebuild              | 71 ++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.27.8-r1.ebuild b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.27.8-r1.ebuild
new file mode 100644
index 000000000000..962c0e637267
--- /dev/null
+++ b/kde-plasma/kdeplasma-addons/kdeplasma-addons-5.27.8-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="Extra Plasma applets and engines"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+alternate-calendar networkmanager share webengine"
+
+RESTRICT="test" # bug 727846
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/krunner-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kunitconversion-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	alternate-calendar? ( dev-libs/icu:= )
+	networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package alternate-calendar ICU)
+		$(cmake_use_find_package networkmanager KF5NetworkManagerQt)
+		$(cmake_use_find_package share KF5Purpose)
+		$(cmake_use_find_package webengine Qt5WebEngine)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Disk quota applet" sys-fs/quota
+	fi
+	ecm_pkg_postinst
+}