[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

["Matt Turner" <mattst88@gentoo.org>]

commit:     5dbdb0a891c5bc2d8d942aacce138a101404e9d6
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sun Sep  3 22:07:27 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Sep 18 13:29:20 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5dbdb0a8

net-misc/gnome-remote-desktop: Version bump to 45_rc

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32596
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-45_rc.ebuild              | 76 ++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index 98f36af95cd8..963248c3a547 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-remote-desktop-44.2.tar.xz 199876 BLAKE2B a959e6ca1f72660138640c4f6edfd5ee8bb4185d27d55456fcdee2eaa38e09ac5a76b0bfbf6395c9725f2cb4fa857f3064379d9824810657ea9c046738803411 SHA512 2e310cd926e0ed6fd28406a56e4d4ba239b9817b035231f66b648a98e08a5c7a7d810a2b786292aa39a7c67ca17af3de92dce4a6031a4f72166d667b8f498bd0
 DIST gnome-remote-desktop-45.alpha.tar.xz 204532 BLAKE2B c9a985b2105c871d3a167d3003a35ad51c30a0b99430ab1795240e3fb17c362532bd06413baf041e805ec82a64639738e47d04a10b3e92d86270f2438eab3ea6 SHA512 047488a3c2131cb0a52b6378e8a4edc70eae5b2d9b2f4a53dd83bc7d46ca4a3b87a59817ec31a674b8be1e5b4e997e0b4d504fb03cb54149aa0ed25789a31752
+DIST gnome-remote-desktop-45.rc.tar.xz 210708 BLAKE2B 4914490b4be2a3e801fdf61085d042dd7ce48b3afebe2088eb8402e1a3498035afe974b4842b18a3302bb34b0a376aaf0dc98cc748b14c19d0d4ca2d388b87db SHA512 1aea24c27c45d343821abe2cb4429afdba14cd636885bdac9f80bf811732e33249bb24632ee723dbe609a77488434051e4f109570da93397cd1e25aba96de1d0

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-45_rc.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-45_rc.ebuild
new file mode 100644
index 000000000000..d7c4a7f43cf6
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-45_rc.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="aac doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc ) aac? ( rdp )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libei-1.0.901
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.10.0:=[server]
+		>=sys-fs/fuse-3.9.1:3
+		>=x11-libs/libxkbcommon-1.0.0
+
+		aac? (
+			media-libs/fdk-aac:=
+		)
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use aac fdk_aac)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		-Dtests=false  # Tests run xvfb-run directly
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}