[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdex/

["Matt Turner" <mattst88@gentoo.org>]

commit:     848a88bab444808a159ad83b9de32b1d21d74280
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sat Sep 16 23:37:21 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Sep 17 01:42:58 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=848a88ba

dev-libs/libdex: Version bump to 0.4.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32861
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libdex/Manifest            |  1 +
 dev-libs/libdex/libdex-0.4.0.ebuild | 60 +++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/libdex/Manifest b/dev-libs/libdex/Manifest
index 4e276d630cfd..7c1b3eb4100a 100644
--- a/dev-libs/libdex/Manifest
+++ b/dev-libs/libdex/Manifest
@@ -1,2 +1,3 @@
 DIST libdex-0.2.0.tar.xz 91648 BLAKE2B 258193b29082024cce30d5e20903f1ba6a3c8e566652d341845178797126796fcc1cf628636de02ba9776cb9d8ff5d38c24f10f269fcd9acbc0cdbb1c0918d8b SHA512 db54fa974af97e59e7a21c19be73db8fec6565377ce313a3532435845d3571216d6617f9a8db500019390d85677ca6f30be3f9a36c60240c8130ae0834826a65
 DIST libdex-0.3.1.tar.xz 95460 BLAKE2B b79e53cde3c1cafe086a0ebb1af74d8c6a05d38bd6e2a74b363fe6b07ab7483014a7caef59ba38176b16df35c92a8f86b9f3a320dc100cc668d915ab3b31d430 SHA512 52ded12bdd088839c7f5bcac24b09667183fe2d515472b41cf7725b4d031b4817e3c043e9b377ccdd2a09c52825ba16f5f368b96d33d35f23fad5264b9225eb9
+DIST libdex-0.4.0.tar.xz 95468 BLAKE2B d45760dd826835cb2e5bffe1a69b7fcfb4b20fcfb55c119fc3175ae80e2c9b6d34d3df5c653075ed2832183f2c76b3dcaf2509977fe9b79f1dabbb59a3301602 SHA512 806d0c6cb7fe9cd0bdf4e85cf93b9bc67ee11bce0e18ba6c5eb8b075e2a3d22359cf58374b6f07e558f8595b24093c052f4e05763104163b46bec0371efbb295

diff --git a/dev-libs/libdex/libdex-0.4.0.ebuild b/dev-libs/libdex/libdex-0.4.0.ebuild
new file mode 100644
index 000000000000..71b799ea6e23
--- /dev/null
+++ b/dev-libs/libdex/libdex-0.4.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala
+
+DESCRIPTION="Deferred Execution library for GNOME and GTK"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdex"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="gtk-doc +introspection sysprof test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	>=sys-libs/liburing-0.7:=
+	introspection? ( dev-libs/gobject-introspection:= )
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dexamples=false
+		$(meson_use vala vapi)
+		$(meson_feature introspection)
+		$(meson_use sysprof)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}