[gentoo-commits] repo/gentoo:master commit in: gui-libs/gtksourceview/

["Matt Turner" <mattst88@gentoo.org>]

commit:     9e7d0c0ba2e058a76c9b42c096bcf28e2078ce65
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sun Sep 17 00:06:07 2023 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Sep 17 01:42:57 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e7d0c0b

gui-libs/gtksourceview: Version bump to 5.10.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32864
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gui-libs/gtksourceview/Manifest                    |  1 +
 gui-libs/gtksourceview/gtksourceview-5.10.0.ebuild | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
index 227b6c6b3e79..63f5ad4c74a0 100644
--- a/gui-libs/gtksourceview/Manifest
+++ b/gui-libs/gtksourceview/Manifest
@@ -1 +1,2 @@
+DIST gtksourceview-5.10.0.tar.xz 1255564 BLAKE2B a105d118716f8e61beb4bb17b8e64dacdc42f1fcfac805a9b517431a4db4da92aea82ba7b042556bc222d8a6406cbe00281c5513c6e55b7517048dae17cf83a5 SHA512 c8fb377c0f65fff35fe764c98d40a399b2f3982bfb7e25512b50f4f3c31b226d4775e136fc4be682b2e44a3b643cefd01d195c9a61f5c3ca81d15bef0093e47a
 DIST gtksourceview-5.8.0.tar.xz 1253152 BLAKE2B 62806fbcced82fec3bdb3ec056dfe5d74db0c4cc039b6f0f18993872b9b082f1190698b0aca966bafc07c29d5ec7d37018c62e5142de0b426742cbe3ddac9f94 SHA512 370be5e8040f68eeef5fc6dec3e0ff9cbcf64a6ad162e228cddf07f6d493c762f37c89010073d4d850ec8c6ffa45c4697f5d9eb8c32de5fffc7ec97f44911d3b

diff --git a/gui-libs/gtksourceview/gtksourceview-5.10.0.ebuild b/gui-libs/gtksourceview/gtksourceview-5.10.0.ebuild
new file mode 100644
index 000000000000..622cee0bfad5
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.10.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx xdg
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+
+IUSE="gtk-doc +introspection sysprof +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.6:4[introspection?]
+	>=dev-libs/libxml2-2.6:2
+	introspection? ( >=dev-libs/gobject-introspection-1.70.0:= )
+	>=dev-libs/fribidi-0.19.7
+	media-libs/fontconfig
+	x11-libs/pango[introspection?]
+	>=dev-libs/libpcre2-10.21:=[-recursion-limit(-)]
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall_tests=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests fail in test-regex with libpcre2[recursion-limit] - https://gitlab.gnome.org/GNOME/gtksourceview/-/issues/255
+	# Ensured OK via USE dep, as it would mean issues in real usage for syntax highlighting as well
+	virtx meson_src_test --timeout-multiplier=5
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/${PN}-5/language-specs
+	newins "${FILESDIR}"/5-gentoo.lang gentoo.lang
+
+	if use gtk-doc ; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}